Dans ce tutoriel, nous découvrirons deux méthodes permettant d’ajouter un nombre spécifié (n) de lignes vides aux résultats de la fonction SEQUENCE dans Google Sheets. Nous aborderons à la fois les résultats à une seule colonne et ceux basés sur une grille.
Par exemple, la formule suivante renverra les nombres de 1 à 10 dans une colonne :
=SEQUENCE(10)Pour obtenir des nombres séquentiels dans une grille, c’est-à-dire 10 lignes sur 4 colonnes, vous pouvez utiliser la formule suivante :
=SEQUENCE(10, 4)Nous utiliserons une formule simple pour ajouter n lignes vides au résultat de la fonction SEQUENCE dans une seule colonne.
En ce qui concerne la sortie en grille, nous utiliserons une formule légèrement plus complexe qui fonctionnera également dans le cas de la colonne unique.
Ajout de N lignes vides au résultat de la fonction SEQUENCE à une seule colonne
Avant d’entrer une formule qui renvoie un résultat de tableau, assurez-vous d’avoir suffisamment de cellules vides, sinon vous obtiendrez une erreur #REF!.
Vous pouvez utiliser la formule suivante dans Google Sheets si vous souhaitez obtenir les numéros de séquence de 1 à 10 avec 2 lignes vides entre eux :
Formule #1:
=TOCOL(IFNA(HSTACK(SEQUENCE(10),,)))Pour ajouter 5 lignes vides au résultat de la fonction SEQUENCE à une seule colonne, utilisez la formule suivante :
Formule #2:
=TOCOL(IFNA(HSTACK(SEQUENCE(10),,,,,)))La valeur de ‘n’ est déterminée par le nombre de virgules immédiatement après la fonction SEQUENCE, que j’ai mis en évidence dans les formules ci-dessus.
Voici le détail de la Formule #1 :
- SEQUENCE(10) : renvoie 10 nombres séquentiels de 1 à 10.
- HSTACK(…, ) : ajoute deux cellules vides.
- IFNA(…) : supprime les valeurs d’erreur et les remplace par une chaîne vide.
- TOCOL(…) : convertit le tableau tridimensionnel (nombres de séquence dans la première colonne et deux colonnes vides) en une seule colonne.
La sortie de TOCOL sera deux cellules vides insérées entre chaque nombre de séquence.
Ajout de N lignes vides aux résultats de la fonction SEQUENCE en grille
Contrairement à notre exemple précédent, ce scénario peut ne pas être courant. Mais dans certains cas, vous pouvez utiliser la fonction SEQUENCE pour obtenir un tableau à 2 dimensions comme suit :
=SEQUENCE(5, 4)Cela renverra un tableau de 5 lignes sur 4 colonnes où la première ligne contiendra les numéros de 1 à 4, la deuxième ligne de 5 à 8, la troisième ligne de 9 à 12, et ainsi de suite.
Comment insérer un nombre spécifié de lignes vides dans une grille de nombres séquentiels dans Google Sheets ?
Voici un exemple.
Formule #3:
=LET(seq, SEQUENCE(5, 4), col, UNIQUE(CHOOSECOLS(seq, 1)), added, REDUCE("", col, LAMBDA(a, d, IFNA(VSTACK(a, FILTER(seq, col=d),,)))), FILTER(added, SEQUENCE(ROWS(added))<>1))La formule ci-dessus générera la séquence avec 2 lignes vides ajoutées entre les éléments.
Les virgules dans le VSTACK, immédiatement après la fonction FILTER, contrôlent le nombre de lignes vides insérées.
Pour ajouter 3 lignes vides à une séquence en grille de taille 10 lignes sur 5 colonnes, remplacez SEQUENCE(5, 4) par SEQUENCE(10, 5) et VSTACK(a, FILTER(seq, col=d),,) par VSTACK(a, FILTER(seq, col=d),,,).
Qui plus est ! Vous pouvez même utiliser cette formule pour insérer des lignes vides entre des nombres séquentiels dans une seule colonne. Il vous suffit d’ajuster la SEQUENCE en conséquence. Par exemple, au lieu de la syntaxe SEQUENCE(lignes, colonnes), utilisez SEQUENCE(lignes).
Cette formule est légèrement complexe, mais la comprendre clarifiera la manière dont la formule ajoute des lignes vides dans les résultats de la fonction SEQUENCE en 2D dans Google Sheets.
Décryptage de la formule
Nous utilisons la fonction LET pour nommer les expressions de valeur, ce qui nous permet d’utiliser ces noms dans les expressions suivantes ou dans la formule elle-même. Cela réduit la répétition et améliore les performances globales de la formule.
Syntaxe :
LET(nom1, expression_de_valeur1, [nom2, ...], [expression_de_valeur2, ...], formule_expression)Noms et expressions de valeur :
- seq : SEQUENCE(5, 4) crée une grille de 5×4 de nombres de 1 à 20.
- col : UNIQUE(CHOOSECOLS(seq, 1)) extrait les valeurs uniques de la première colonne de seq.
- added : REDUCE(« », col, LAMBDA(a, d, IFNA(VSTACK(a, FILTER(seq, col=d),,)))) est la partie clé de la formule qui insère n (ici, 2) lignes vides entre les nombres séquentiels.
Voici comment fonctionne REDUCE :
REDUCE(« », col, LAMBDA(a, d, …) : la fonction REDUCE prend deux arguments : une valeur initiale (une chaîne vide dans notre formule) et un tableau (col).
La valeur initiale est définie comme a, et chaque valeur dans col, c’est-à-dire {1; 5; 9; 13; 7} (veuillez vous référer à l’image ci-dessus), est définie comme d.
La fonction REDUCE itère à travers col, en appliquant une fonction à chaque valeur unique d. d sera la première valeur de col dans la première ligne, la deuxième valeur de col dans la deuxième ligne, et ainsi de suite.
LAMBDA(a, d, …) : définit une fonction anonyme qui traite chaque valeur.
IFNA(VSTACK(a, FILTER(seq, col=d),,)) : filtre les lignes de seq où col=d, les empile en dessous de a, puis empile deux cellules vides en dessous de cela. IFNA gère les erreurs potentielles dues à l’empilement d’un tableau unidimensionnel sous un tableau 2D.
La formule extrait chaque ligne de la grille de séquence et ajoute des lignes vides en dessous à l’aide de VSTACK. En résumé, elle réarrange la grille de données.
Expression de la formule :
Puisque la valeur initiale dans l’accumulateur est une chaîne vide, il y aura une ligne vide en haut du résultat dans ‘added’.
FILTER(added, SEQUENCE(ROWS(added))<>1)Supprime la première ligne de ‘added’ car elle est probablement une ligne vide résultant de la première itération de REDUCE.
Ressources
Ce tutoriel couvre l’ajout de n lignes vides aux résultats de la fonction SEQUENCE (unidimensionnels ou 2D) dans Google Sheets. Voici quelques tutoriels qui abordent un sujet similaire.
- Sauter les lignes vides dans la numérotation séquentielle dans Google Sheets
- Comment remplir les dates séquentielles en excluant les week-ends dans Google Sheets
- Attribuer les mêmes numéros séquentiels aux doublons dans une liste dans Google Sheets
- Remplir automatiquement des dates séquentielles lorsqu’une valeur est saisie dans la colonne suivante dans Google Sheets
- Insérer des numéros séquentiels en sautant les lignes masquées | filtrées dans Google Sheets
- Numérotation séquentielle dans les cellules fusionnées dans Google Sheets
- Comment insérer des lignes vides à l’aide d’une formule dans Google Sheets
- Comment insérer automatiquement une ligne vide sous chaque groupe dans Google Sheets
- Insérer des lignes vides pour séparer les débuts/fins de semaine dans Google Sheets
N’hésitez pas à consulter ces ressources pour tirer le meilleur parti des fonctionnalités de numérotation séquentielle dans Google Sheets.
