La fonction UNIQUE dans Google Sheets est conçue pour renvoyer des valeurs uniques ou distinctes à partir d’une liste ou d’une plage de tableaux. Elle peut fonctionner soit ligne par ligne, soit colonne par colonne, selon vos préférences.
Les termes « valeurs uniques » et « valeurs distinctes » sont souvent utilisés de manière interchangeable, mais dans ce contexte, il y a une différence de sens entre les deux.
-
Unique : Par exemple, dans une liste de noms, la fonction UNIQUE peut éliminer les occurrences multiples des noms, le cas échéant, et fournir une liste de noms uniques.
-
Distinct : Dans la même liste de noms, la fonction ne renverra que les noms qui n’ont pas de doublons ou d’occurrences multiples.
Il convient de noter que dans certains tutoriels en ligne, vous ne trouverez peut-être pas cette distinction. Initialement, la fonction n’avait pas de fonctionnalité distincte ; elle a été ajoutée par la suite. Un autre changement notable dans la fonction au fil des ans est sa capacité améliorée à gérer à la fois des ensembles de données verticaux et horizontaux.
Syntaxe et arguments de la fonction UNIQUE dans Google Sheets
Syntaxe de la fonction UNIQUE dans Google Sheets :
UNIQUE(plage, [par_colonne], [exactement_une_fois])
Arguments :
-
plage : La plage ou le tableau à partir duquel renvoyer les lignes ou les colonnes uniques.
-
par_colonne : Utilisez les valeurs booléennes VRAI ou FAUX. VRAI signifie unique/distinct par colonne, et FAUX signifie unique/distinct par ligne.
-
exactement_une_fois : Utilisez les valeurs booléennes VRAI ou FAUX. VRAI renverra toutes les lignes/colonnes distinctes qui apparaissent exactement une fois. FAUX supprimera les occurrences multiples et renverra le reste des lignes/colonnes.
Les deux derniers arguments sont facultatifs et définis par défaut sur FAUX.
Exemples de la fonction UNIQUE dans Google Sheets
Dans cette section d’exemples basiques, explorons la compréhension de tous les arguments de la fonction UNIQUE.
Cela aidera à clarifier la distinction entre les valeurs uniques et distinctes dans la perspective de la fonction UNIQUE, ainsi qu’à illustrer le fonctionnement de la fonction avec des données à la fois dans des lignes et des colonnes. Nous commencerons par examiner les données disposées dans des lignes.
Renvoyer des valeurs uniques et distinctes dans une liste par ligne
Dans les exemples suivants, j’ai une liste de noms dans la plage B2:B7, et ils sont {Alice, Ethan, Olivia, Sophia, Sophia, Alice}.
Comme vous pouvez le voir, « Alice » et « Sophia » apparaissent deux fois. Pour obtenir les noms uniques de cette plage de données verticales, vous pouvez utiliser la formule suivante :
=UNIQUE(B2:B7, FAUX, FAUX)
Où :
- plage : B2:B7
- par_colonne : FAUX
- exactement_une_fois : FAUX
Cela renverra les noms {Alice, Ethan, Olivia, Sophia}.
Depuis que les deux derniers arguments sont facultatifs et que leurs valeurs par défaut sont FAUX, vous pouvez les omettre dans la formule :
=UNIQUE(B2:B7)
C’est l’utilisation la plus courante de la fonction UNIQUE dans Google Sheets.
Dans la liste, les noms distincts sont « Ethan » et « Olivia ». Pour obtenir ces noms, utilisez la formule UNIQUE suivante :
=UNIQUE(B2:B7, FAUX, VRAI)
Où :
- plage : B2:B7
- par_colonne : FAUX
- exactement_une_fois : VRAI
Renvoyer des valeurs uniques et distinctes dans une liste par colonne
Si la liste ci-dessus de noms est dans la plage B2:G2, disposée en colonnes, vous devez remplacer FAUX dans le deuxième argument, qui est par_colonne, par VRAI dans les deux formules unique et distincte.
Voici des exemples :
La formule dans la cellule B5 renvoie les noms uniques dans la plage de données horizontale.
=UNIQUE(B2:G2, VRAI, FAUX)
Où :
- plage : B2:G2
- par_colonne : VRAI
- exactement_une_fois : FAUX
La formule suivante dans la cellule B6 renvoie les noms distincts :
=UNIQUE(B2:G2, VRAI, VRAI) // renvoie les noms distincts
Où :
- plage : B2:G2
- par_colonne : VRAI
- exactement_une_fois : VRAI
Dans les exemples ci-dessus, nous avons utilisé la fonction UNIQUE soit dans une seule colonne, soit dans une seule ligne. Que se passe-t-il avec une plage de tableaux ?
Utilisation de la fonction UNIQUE dans un tableau dans Google Sheets
Ici, j’ai un tableau avec trois colonnes, et les données sont disposées en lignes dans la plage A1:C5.
La formule dans la cellule F1 est :
=UNIQUE(A1:C5)
Lorsque vous utilisez un tableau à plusieurs colonnes avec des données disposées en lignes, la fonction UNIQUE prend en compte l’ensemble de la ligne pour évaluer les doublons.
Dans ce sens, A3:C3 et A4:C4 sont des doublons, donc la fonction en supprime un.
Remarque : Pour obtenir les lignes distinctes de cette plage, vous pouvez utiliser la formule suivante : =UNIQUE(A1:C5, FAUX, VRAI)
Cela peut être un inconvénient dans certains cas. Voir l’exemple ci-dessous pour comprendre cela.
Explorer une alternative
Dans cet exemple, il y a deux colonnes dans la plage source fournie A2:B, la première colonne contient les noms des participants et la deuxième colonne contient leurs scores aux tests.
Si un participant a passé plusieurs tests et que ses scores sont identiques, la fonction UNIQUE peut supprimer la ligne en double.
Mais si ses scores sont différents, elle ne le peut pas, car la fonction évalue l’ensemble de la ligne pour trouver les doublons, pas une colonne particulière.
Nous pouvons utiliser la fonction SORTN à la place de la fonction UNIQUE pour résoudre ce problème. Voici un aperçu.
= SORTN (A2: B, 9^9, 2, 1, 1) // renvoie les premières occurrences de noms
Remarque : Vous pouvez trier les données par noms par ordre croissant et les scores par ordre décroissant avant d’appliquer SORTN pour obtenir les lignes avec les scores les plus élevés. Exemple : =SORTN(SORT(A2:B, 1, TRUE, 2, FALSE), 9^9, 2, 1, 1)
Vous pouvez spécifier n’importe quelle colonne individuelle contenant les doublons dans cette formule.
Le nombre 1, qui est l’avant-dernier dans la formule ci-dessus, indique la colonne qui contient les doublons.
Pour en savoir plus à ce sujet, veuillez consulter : Comment appliquer Unique dans des colonnes sélectionnées dans Google Sheets
Comment supprimer les cellules vides dans le résultat de la fonction UNIQUE dans Google Sheets
Nous utilisons souvent la fonction UNIQUE avec des données disposées ligne par ligne dans Google Sheets. Explorons comment éliminer les cellules vides du résultat UNIQUE.
La fonction UNIQUE inclut les cellules vides dans ses résultats. Si la plage contient une ou plusieurs cellules vides, la formule renverra une seule cellule vide.
Si la plage est B2:B, vous pouvez utiliser la fonction TOCOL avec la fonction UNIQUE pour supprimer la cellule vide.
=TOCOL(UNIQUE(B2:B), 1)
Cette étape est cruciale car nous utilisons généralement le résultat UNIQUE comme critère pour regrouper des données, et la présence d’une cellule vide peut poser problème.
Remarque : Si vous utilisez la fonction UNIQUE dans une plage à plusieurs colonnes et que vous souhaitez supprimer les lignes vides, veuillez vous référer à ce tutoriel : Filtrer si la ligne entière est vide dans Google Sheets
Conclusion
La fonction UNIQUE est sensible à la casse dans Google Sheets, mais insensible à la casse dans Excel. Veuillez garder cette distinction à l’esprit si vous utilisez les deux applications.
La sensibilité à la casse est un sujet complexe en ce qui concerne la fonction UNIQUE. Pour une exploration plus approfondie, consultez notre tutoriel séparé ici : Unique insensible à la casse dans Google Sheets.
En plus de TOCOL, comme expliqué précédemment, vous pouvez utiliser des fonctions telles que SORT, FLATTEN, QUERY, etc., en combinaison avec la fonction UNIQUE dans Google Sheets.
Vous pouvez utiliser la fonction SORT pour organiser les résultats uniques ou distincts renvoyés par la formule par ordre croissant ou décroissant.
SORT(UNIQUE(plage))
Pour gérer des valeurs uniques ou distinctes dispersées dans des cellules, vous pouvez utiliser la fonction FLATTEN à l’intérieur de la fonction UNIQUE en utilisant la syntaxe suivante :
=UNIQUE(FLATTEN(plage))
C’est tout. Merci de rester avec nous. Profitez-en !
