Comment arranger les nombres dans un tableau en bas, moyen et haut dans Google Sheets ? Il n’y a pas de commande ou de fonction spécifique dans Google Sheets pour séparer les nombres en groupes individuels. J’ai écrit une formule à cet effet.
Dans ce tutoriel Google Sheets, apprenons à séparer ou à arranger un tableau de nombres en bas, moyen et haut en utilisant une formule.
En plus de cela, vous pouvez apprendre à tester la position d’un nombre dans un tableau. Cela signifie si le nombre spécifié se situe dans la catégorie basse, moyenne ou haute.
Pour la première solution, j’utiliserai une formule basée sur PERCENTRANK en combinaison avec la fonction FILTER. Pour la deuxième solution, en plus de PERCENTRANK, j’utiliserai le test logique IF.
Comment arranger un tableau de nombres en bas, moyen et haut dans Google Sheets
J’ai les nombres suivants dans un tableau (A2:A).
Le tableau de nombres se trouve en A2:A. J’ai utilisé trois formules pour arranger les nombres en A2:A en bas, moyen et haut, c’est-à-dire en trois plages distinctes.
Les formules se trouvent dans les cellules E2 (bas), F2 (moyen) et G2 (haut).
Voici la formule principale qui nous aidera à filtrer les nombres en A2:A en bas, moyen et haut dans Google Sheets.
Dans la cellule C2, insérez la formule de tableau PERCENTRANK suivante.
=ArrayFormula(PERCENTRANK(A2:A,A2:A))
La formule ci-dessus renvoie les rangs en pourcentage, c’est-à-dire le percentile de tous les nombres en A2:A dans l’ensemble de données (A2:A).
La valeur MIN dans l’ensemble de données obtiendra un percentile de 0 et la valeur MAX dans l’ensemble de données obtiendra un percentile de 1. Cela signifie que les percentiles des nombres vont de 0 à 1.
Ainsi, pour classer les nombres en trois tableaux distincts, nous devons suivre la logique suivante.
Bas :
Pour arranger le tableau de nombres en A2:A dans la catégorie Bas, nous devons filtrer A2:A si C2:C <= 1/3.
Moyen :
Filtrer A2:A si C2:C > 1/3 et C2:C <= 1/3*2.
Haut :
Filtrer A2:A si C2:C > 1/3*2.
Basé sur ce qui précède, nous pouvons écrire la formule en utilisant la fonction FILTER comme suit.
E2 Formule #1:
=filter($A$2:$A,$C$2:$C<=1/3)
F2 Formule #2:
=filter($A$2:$A,$C$2:$C>1/3,$C$2:$C<=1/3*2)
G2 Formule #3:
=filter($A$2:$A,$C$2:$C>1/3*2)
Enfin, vous pouvez remplacer $C$2:$C dans les trois formules par la formule C2, c’est-à-dire PERCENTRANK(A2:A,A2:A), et supprimer la formule de C2.
De cette manière, nous pouvons arranger un tableau de nombres en bas, moyen et haut dans Google Sheets.
Tester si une valeur se situe en bas, moyen ou haut dans une plage
Je peux expliquer ce sujet sans trop d’effort en utilisant l’image GIF ci-dessous.
La formule dans la cellule I2 trouve la position d’une valeur dans un ensemble de données.
Ici, nous testons un nombre externe (veuillez voir la cellule H2) dans le tableau (A2:A) pour sa position (rang). Cela signifie si le nombre dans la cellule H2 se situe en bas, moyen ou haut dans la plage.
La logique est la même que précédemment. Mais ici, nous utiliserons IF au lieu de FILTER.
=ifna( IF( PERCENTRANK( A2:A,H2 )<1/3, "Bas", if( PERCENTRANK(A2:A,H2 )<1/3*2, "Moyen", "Haut" ) ),"Le nombre n'existe pas dans le tableau" )
La formule PERCENTRANK renvoie le percentile du nombre en F2 dans la plage A2:A. IF teste le percentile comme suit.
Si le rang en pourcentage est ;
- inférieur à 1/3, renvoyer « Bas »
- supérieur à 1/3 et inférieur ou égal à 1/3*2, renvoyer « Moyen »
- sinon, renvoyer « Haut »
La fonction IFNA est utilisée pour le dernier paramètre, c’est-à-dire pour renvoyer le texte « Le nombre n’existe pas dans le tableau ». C’est tout ce qu’il y a à savoir sur l’arrangement d’un tableau de nombres en bas, moyen et haut dans Google Sheets.
Merci de votre attention, profitez-en bien!
