Un modèle de vue calendrier dans Google Sheets peut vous aider à visualiser vos données (enregistrements) de manière facilement compréhensible.
Dans Google Sheets, nous pouvons créer et afficher des rapports sous forme tabulaire en utilisant des fonctions telles que FILTRE, REQUÊTE ou Tableau croisé dynamique.
Cependant, le mode de vue calendrier personnalisé dans Google Sheets affiche les informations dans un format de calendrier standard basé sur le mois et l’année sélectionnés par l’utilisateur, ainsi que d’autres paramètres dans la feuille de données source.
Vous pouvez naviguer à travers le calendrier par mois et par année. Les données correspondantes seront affichées sous chaque date du mois et de l’année sélectionnés, en fonction de la disponibilité des données dans la feuille source.
Vous pouvez utiliser mon modèle de vue calendrier dans Google Sheets pour afficher des données de vente, des données d’achat, des données de pointage des employés, des listes de tâches, suivre vos événements et réunions, et bien plus encore.
Caractéristiques
Le modèle de vue calendrier personnalisé dans Google Sheets prend en charge différents types de données. Il s’agit de texte, de nombres, de temps et de durée.
Si plusieurs enregistrements sont présents pour une date donnée, les données seront agrégées en fonction du type de données.
Les nombres et les durées seront agrégés (somme). Les textes seront rendus uniques, puis concaténés.
La fusion de plusieurs colonnes est également prise en charge. Cela est utile lorsque vous avez des adresses saisies dans des colonnes telles que le nom, l’e-mail, le numéro de téléphone, etc., dans leurs propres colonnes.
Nous verrons plus en détail les caractéristiques ci-dessus dans la section des exemples ci-dessous. Avant cela, vous pouvez télécharger (faire une copie de) mon modèle de vue calendrier ci-dessous.
Utilisation d’un modèle de vue calendrier personnalisé dans Google Sheets
Le fichier modèle contient deux feuilles : Master et CV.
La feuille Master contient neuf champs prédéfinis (colonnes) :
- Colonne 1 : Date
- Colonnes 2 à 6 : Texte
- Colonnes 7 et 8 : Temps
- Colonne 9 : Durée ou nombre
Nous ne remplirons que les données dans les colonnes nécessaires. La feuille CV se mettra automatiquement à jour pour refléter les données de la feuille Master.
Remarque : Les valeurs saisies dans les colonnes 2 à 6 seront combinées en une seule valeur dans la vue calendrier.
Voyons maintenant trois exemples.
1. Affichage du calendrier journalier des heures d’un employé
Comme nous l’avons vu précédemment, la feuille Master est formatée pour prendre en charge différents types de données. Nous commencerons par saisir les données de pointage d’un employé.
Pour afficher le calendrier journalier des heures d’un employé, nous avons besoin de trois champs : Date, Heure de début et Heure de fin.
Nous remplirons les données dans les colonnes A, G et H, qui correspondent respectivement aux colonnes 1, 7 et 8.
Supprimez les étiquettes de champ dans les colonnes inutilisées B1:F1 et I1.
Voici la vue calendrier des heures d’entrée et de sortie de l’employé que nous avons saisies dans la feuille Master.
Notes :
- Si un employé a plusieurs enregistrements (entrée et sortie) pour la même date, l’heure la plus tôt sera considérée comme heure d’entrée et l’heure la plus tardive sera considérée comme heure de sortie.
- Vous devez entrer manuellement les textes « Début » et « Fin » dans la colonne A de la feuille CV, aux lignes correspondantes. Veuillez vous référer à l’image ci-dessus.
2. Vue calendrier du journal des rendez-vous dans Google Sheets
Dans cet exemple, les données à traiter dans la vue calendrier sont un journal de rendez-vous dans Google Sheets. Les champs (colonnes) suivants seront nécessaires :
- Date (Colonne 1)
- Nom (Colonne 2)
- E-mail (Colonne 3)
- Téléphone (Colonne 4)
- Lieu de la réunion (Colonne 5)
- Participants (Colonne 6)
- Heure (Colonne 7)
Voici comment remplir les informations pertinentes dans notre feuille Master :
Une fois que vous avez terminé de saisir vos données dans la feuille Master, allez à la feuille CV pour voir les résultats.
Voici la vue calendrier du journal de rendez-vous dans Google Sheets.
3. Liste de tâches dans une vue calendrier dans Google Sheets
Avoir une liste de tâches est un bon moyen de hiérarchiser vos tâches personnelles ou professionnelles.
Si vous avez déjà créé ou prévoyez de créer une feuille de calcul pour une liste de tâches, l’utilisation de Google Sheets est une bonne idée.
Savez-vous pourquoi ?
Parce que Google Sheets est un programme de feuille de calcul basé sur le cloud auquel vous pouvez accéder depuis votre téléphone portable ou votre ordinateur, que vous soyez chez vous ou au travail.
Vous pouvez utiliser mon modèle pour saisir votre liste de tâches et les visualiser dans la vue calendrier.
Voici les étapes pour utiliser mon modèle de vue calendrier pour une liste de tâches dans Google Sheets :
- Dans la feuille Master, saisissez les dates des tâches dans la colonne A et les tâches dans la colonne B.
- Accédez à la feuille CV et sélectionnez le mois dans la cellule G1 et l’année dans la cellule H1.
- La liste de tâches sera immédiatement disponible pour être visualisée.
Modèle de vue calendrier Google Sheets : Formules clés
Nous avons plusieurs formules de tableau dans la feuille CV. Elles se trouvent dans la plage B5:B34. Certaines d’entre elles servent à remplir le calendrier dynamique, et ces formules se trouvent dans les cellules B5, B10, B15, B20, B25 et B30.
Entre ces cellules, nous avons les formules qui récupèrent les valeurs pour la vue calendrier, et voici ces formules clés.
B6 : La formule suivante dans la cellule B6 permet de récupérer les valeurs de texte des colonnes B à F (2 à 6) de la feuille Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,source_txt,Master!$B$2:$F,header,Master!$B$1:$F$1,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,TEXTJOIN(CHAR(10),TRUE,UNIQUE(IFNA(FILTER(IF(LEN(source_txt),header&": "&source_txt,),DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))))))
Elle trie et combine les textes.
B7 : La formule suivante dans la cellule B7 permet de récupérer les valeurs de temps de la colonne G (7) de la feuille Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$G$2:$G,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))))))))
Elle renvoie l’heure la plus tôt en cas de plusieurs entrées pour la même date.
B8 : La formule suivante dans la cellule B8 permet de récupérer les valeurs de temps de la colonne H (8) de la feuille Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$H$2:$H,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))),1,0,1,0)))))
Elle renvoie l’heure la plus tardive en cas de plusieurs entrées pour la même date.
B9 : La formule suivante dans la cellule B9 permet de récupérer les valeurs de durée ou de nombres de la colonne I (9) de la feuille Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$I$2:$I,month_txt,$G$1,calendar_dt,B5:H5,result,MAP(calendar_dt,LAMBDA(dtd,IFNA(SUM(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))),IF(result>0,result,)))
Elle renvoie la valeur agrégée (somme) en cas de plusieurs entrées pour la même date.
Copiez les formules ci-dessus dans les cellules B6 à B9 et collez-les dans les cellules B11, B16, B21, B26 et B31.
Conclusion
J’ai donné trois exemples pour vous montrer comment utiliser mon modèle de vue calendrier dans Google Sheets.
Vous avez peut-être remarqué que aucun d’entre eux n’utilise la 9e colonne de durée/numérique (I) de la feuille Master. Voici comment l’utiliser.
Supposons que vous souhaitiez afficher vos dépenses quotidiennes dans la vue calendrier.
Saisissez les dates dans la colonne A, les intitulés de dépenses (descriptions) dans la colonne B et le montant dans la colonne I. Si plusieurs dépenses ont lieu le même jour, vous pouvez les traiter de deux manières :
- Saisissez-les sur deux lignes (supposons qu’il y ait deux dépenses). Cela créera deux enregistrements pour la même date. La formule correspondante les fusionnera (agrégera).
- Saisissez-les sur une seule ligne. Saisissez les descriptions séparées par des virgules et additionnez manuellement les dépenses, puis entrez le total dans la colonne I.
De même, vous pouvez utiliser la neuvième colonne pour saisir la durée, par exemple les heures supplémentaires. Vous pouvez le faire vous-même une fois que vous avez consulté les trois exemples ci-dessus.
C’est tout ce qu’il y a à savoir sur le modèle de vue calendrier dans Google Sheets. J’espère que vous avez apprécié.
Autres modèles personnalisés populaires :
- Modèle de calendrier de statut de réservation et de réservation dans Google Sheets.
- Formule de tableau pour diviser les dépenses de groupe dans Google Sheets (modèle).
