Pour compter les tâches terminées dans Google Sheets, nous pouvons utiliser la fonction COUNTIF en combinaison avec d’autres fonctions.
Vous pourriez penser que vous pouvez utiliser COUNTIF ou DCOUNTA seul pour la même chose. Mais ce n’est pas le cas. Cela ne sera possible que si une tâche n’a pas de sous-tâches.
Par exemple, supposons qu’une colonne contienne la chaîne « Terminé » ou des cases à cocher pour montrer les activités terminées.
Si c’est la colonne C, vous pouvez essayer la formule suivante:
=countif(C1:C,"Terminé")
Ou:
=DCOUNTA(C1:C,1,{"Statut";"Terminé"})
Dans le DCOUNTA, j’ai supposé que le libellé du champ dans C1 est « Statut » car c’est une formule de base de données et nécessite une ligne d’en-tête.
Note: Si vous avez des cases à cocher, remplacez « Terminé » dans les formules par TRUE. N’entourez pas TRUE de guillemets doubles car il s’agit d’une valeur logique.
Si vous avez plusieurs groupes et que vous voulez compter uniquement si chaque ligne de chaque groupe a le statut terminé, alors les formules ci-dessus ne seront pas pratiques.
Dans ce tutoriel Google Sheets, j’ai deux types de solutions de formules pour vous. Les deux utilisent COUNTIF. Mais les fonctions de support seront différentes.
Il est temps de passer par un exemple.
Données d’exemple et comptage souhaité
Voyons comment compter les tâches terminées et incomplètes, ici les actions, en fonction de la colonne de statut C dans Google Sheets.
Les données d’exemple ci-dessus montrent les demandes reçues de plusieurs clients pour un article et leurs statuts avec le fournisseur maintenant.
Une entreprise a reçu des demandes de quatre clients – Client A, B, C et D.
Sauf pour l’entreprise B, les commandes des trois autres entreprises ont déjà été satisfaites/réalisées.
Comment compter la colonne de statut si tous les statuts d’une entreprise montrent « Terminé » ?
Selon les données ci-dessus, les résultats souhaités sont les suivants :
Action terminée – 3
Action incomplète – 1
Formules pour compter les tâches terminées dans Google Sheets
Tout d’abord, nous devons trouver un moyen de compter le nombre total de tâches terminées. Ensuite, il sera facile de trouver le nombre total de tâches incomplètes.
Parce que;
Tâches incomplètes totales = Tâches uniques totales – Tâches terminées totales
Vous pouvez trouver plus de détails sous le titre « Formules pour compter les tâches incomplètes dans Google Sheets » à la fin.
Option de formule # 1
Voici la formule à utiliser pour compter le nombre total de tâches entièrement terminées.
=ArrayFormula(countif(IFNA(vlookup(UNIQUE(A2:A),sort(A2:C,3,0),3,0)),"Terminé"))
Insérez la formule ci-dessus dans la cellule F2, qui renverra 3 sur la base des données d’exemple ci-dessus (image # 1).
COUNTIF est la clé, mais nous devons préparer les données avant de l’utiliser. VLOOKUP effectue cette opération avec l’aide de UNIQUE et SORT.
Voici les explications pour chaque étape impliquée dans la formule ci-dessus pour compter les tâches terminées dans Google Sheets.
Explication
Partie 1 de la formule : =UNIQUE(A2:A)
La formule ci-dessus renverra les clients uniques.
Partie 2 de la formule : =sort(A2:C,3,0)
La formule SORT ci-dessus trie les valeurs de la troisième colonne (colonne de statut) par ordre décroissant. Ainsi, les lignes marquées avec l’action « Incomplète » seront en haut.
Partie 3 de la formule : vlookup(UNIQUE(A2:A),sort(A2:C,3,0),3,0)
La partie de formule 3 est la rechercheV. La partie de formule ci-dessus acte comme les clés de recherche dans VLOOKUP, et la partie de formule ci-dessus acte comme sa plage.
Le VLOOKUP renverra les valeurs de la troisième colonne de cette plage.
Dans une plage non triée première colonne, la formule renverra les valeurs à partir de la première occurrence.
Cela signifie que la formule renverra les valeurs comme ci-dessous (deuxième colonne dans le tableau).
Tableau # 1
[Aperçu image ci-dessus]
En utilisant COUNTIF dans ces deux colonnes, nous pouvons compter le nombre de tâches terminées dans Google Sheets.
J’ai utilisé IFNA pour supprimer l’erreur #N/A et COUNTIF pour compter la colonne 2 si la valeur est « Terminé ».
Option de formule # 2
Comparé à la formule ci-dessus, celle-ci est plus courte.
=countif(sortn(sort({A2:A,C2:C},2,0),9^9,2,1,0),"Terminé")
Comme je l’ai dit plusieurs fois, SORTN est l’une des meilleures fonctions de Google Sheets. Voyez à quel point il est utile ici.
Comprenez les parties de la formule.
Ici, la partie de formule précédente 1 (unique) n’est pas applicable.
La partie de formule 2 (tri) est ici. Elle ne nécessite que les colonnes A et B pour le tri.
J’ai donc utilisé {A2:A,C2:C} au lieu de A2:C pour le tri.
Ici aussi, trie la colonne de statut C dans l’ordre décroissant. Veuillez consulter l’image # 2 ci-dessus pour le résultat du tri. La colonne H dans le résultat du tri ne sera pas présente ici.
SORTN supprime les lignes de clients en double en fonction de la colonne 1. Donc le résultat sera similaire au tableau # 1 ci-dessus.
Ici aussi, COUNTIF fait le reste de la partie.
Vous avez deux options de formule pour compter les tâches terminées dans Google Sheets. Que dire du comptage des activités non terminées ?
Formules pour compter les tâches incomplètes dans Google Sheets
J’ai déjà donné une formule générique juste au-dessus de Formula Option # 1 (sous-titre). Veuillez vous y référer en premier.
En utilisant COUNTUNIQUE(A2:A) nous pouvons obtenir le compte total des clients ou des tâches uniques. Selon notre exemple, il sera de 4.
À partir de cela, déduisez la sortie du résultat ci-dessus.
Donc la formule utilisant la formule Option # 1 sera;
=COUNTUNIQUE(A2:A)-ArrayFormula(countif(IFNA(vlookup(UNIQUE(A2:A),sort(A2:C,3,0,1,1),3,0)),"Terminé"))
Et la formule Option # 2 sera;
=COUNTUNIQUE(A2:A)-countif(sortn(sort({A2:A,C2:C},2,0),9^9,2,1,0),"Terminé")
Nous pouvons utiliser l’une ou l’autre des formules ci-dessus pour compter les tâches incomplètes pour les données d’exemple données dans Google Sheets.
C’est tout ! Profitez-en.
Lecture connexe: Marquez les tâches comme terminées une fois que toutes les sous-tâches sont terminées dans Sheets.
