Dans Google Sheets, la mise en forme conditionnelle vous permet de mettre en évidence de manière dynamique des lignes entières en fonction de critères spécifiques. C’est très utile lorsque vous souhaitez rechercher des valeurs dans une plage de cellules et mettre en évidence les lignes correspondantes.
Mettre en évidence des lignes entières en recherchant une clé dans une colonne spécifique dans Google Sheets
Supposons que vous ayez des entrées de dates dans la colonne A et que vous souhaitiez mettre en évidence les lignes où la colonne A contient la date d’aujourd’hui. Voici comment procéder :
- Accédez à la cellule A1 de la feuille où vous souhaitez appliquer la mise en évidence.
- Cliquez sur
Format > Mise en forme conditionnelle. - Dans le champ « Appliquer la règle à la plage », saisissez A5:E100.
- Sélectionnez « La formule personnalisée est » dans le menu déroulant « Règles de mise en forme ».
- Saisissez la formule personnalisée
=INT($A5)=TODAY()dans le champ « Formule personnalisée ». - Choisissez la couleur du texte et du remplissage de cellule de votre choix dans la section « Style de mise en forme ».
- Cliquez sur « Terminé ».
La formule mettra en évidence toutes les lignes contenant la date d’aujourd’hui ou une date/heure contenant la date d’aujourd’hui. Si plusieurs cellules de la colonne A contiennent la date d’aujourd’hui ou l’heure, toutes ces lignes seront mises en évidence.
Pour spécifier une date, un texte ou un nombre spécifique en tant que critère pour mettre en évidence une ligne entière, voici quelques exemples de formules personnalisées :
- Date spécifique :
=INT($A1)=DATE(année, mois, jour) - Texte :
=$A1="Pomme" - Nombre :
=$A1=100 - Nombre avec comparaison :
=$A1>=100 - Horodatage :
=$A1=DATE(année, mois, jour)+TIME(heure, minute, seconde)
Dans tous ces exemples de formules, remplacez $A1 par l’adresse de la première cellule dans la colonne de recherche. Par exemple, si vous souhaitez appliquer cette règle à la plage C2:G10 et que la colonne de recherche est la colonne G, vous devez utiliser $G2.
Astuce : Inclure plusieurs clés de recherche pour la mise en forme conditionnelle
Pour inclure plusieurs clés de recherche, par exemple, mettre en évidence les lignes dans la plage A5:E100 où les valeurs de la colonne B5:B100 correspondent à « Pomme » ou « Orange », utilisez l’opérateur logique OR de la manière suivante :
=OR($B5="Pomme", $B5="Orange")
Rechercher des critères dans plusieurs colonnes et mettre en évidence des lignes entières dans Google Sheets
Dans les exemples précédents, nous avons discuté de la recherche de clés dans une colonne spécifique. Mais que faire si vous devez rechercher des critères dans plusieurs colonnes ?
Par exemple, supposez que vous ayez une plage de cellules de A1 à Z1000 et que vous souhaitiez mettre en évidence les lignes où une cellule de cette plage contient la chaîne de caractères « Pomme ». Vous pouvez utiliser la formule suivante pour la règle de mise en forme conditionnelle :
=XMATCH("Pomme",$A1:Z1)
La fonction XMATCH recherche « Pomme » dans la ligne 1 et renvoie le numéro de colonne s’il est trouvé, ou #N/A s’il ne l’est pas. Si le résultat n’est pas #N/A, les lignes sont mises en évidence. Cela s’applique automatiquement à chaque ligne dans la plage spécifiée dans la mise en forme conditionnelle.
Mettre en évidence une ligne entière à l’aide de VLOOKUP dans Google Sheets
Voici un exemple où mon tableau est dans la plage A3:E11 et je souhaite mettre en évidence la ligne entière contenant la première occurrence du fruit « Myrtille » dans la colonne A3:A11.
Dans ce cas, vous pouvez utiliser la formule VLOOKUP suivante pour la plage « Appliquer à » A3:E11 :
=ROW()=ROW(INDIRECT(CELL("ADDRESS", VLOOKUP("Myrtille", $A$3:$E11, 2, 0))))
Décortiquons la formule :
VLOOKUP("Myrtille", $A$3:$E11, 2, 0): Cette formule VLOOKUP recherche la clé « Myrtille » dans la plage de cellules $A$3:$E11 et renvoie la valeur de la deuxième colonne de la plage. La colonne de résultat n’est pas importante ; la plage contient 5 colonnes, vous pouvez donc spécifier n’importe quelle colonne de 2 à 5.- La fonction CELLS renvoie l’identifiant de la cellule du résultat.
- En enveloppant l’identifiant de cellule avec ROW et INDIRECT, nous obtenons le numéro de ligne du résultat de VLOOKUP.
- La règle compare le numéro de ligne actuel avec le numéro de ligne ci-dessus et met en évidence la ligne correspondante.
Remarque : Si vous souhaitez mettre en évidence la ligne du résultat de VLOOKUP uniquement lorsque le résultat est une valeur spécifique, vous pouvez utiliser la formule suivante :
=AND(VLOOKUP("Myrtille", $A$3:$E11, 2, 0) > 3, ROW() = ROW(INDIRECT(CELL("ADDRESS", VLOOKUP("Myrtille", $A$3:$E11, 2, 0)))))
Cette règle de mise en forme conditionnelle ne s’appliquera que si le résultat est supérieur à 3.
Comment mettre en évidence une ligne correspondante à partir du bas d’un tableau
Pour les mêmes données d’exemple, vous pouvez utiliser la formule XLOOKUP suivante pour mettre en évidence une ligne entière correspondant à une clé à partir du bas du tableau :
=ROW()=ROW(INDIRECT(CELL("ADDRESS", XLOOKUP("Myrtille", $A$3:$A11, $A$3:$A11, , 0, -1))))
Ici, VLOOKUP a été remplacé par XLOOKUP car il peut rechercher de la dernière valeur à la première valeur.
La fonction XLOOKUP recherche « Myrtille » dans $A$3:$A11 et renvoie la valeur de la même plage.
Tous les autres composants de la formule restent les mêmes, tout comme la logique.
Conclusion
En examinant les formules, on remarque un principe clé : l’utilisation du signe dollar ($) avec les références de cellules est cruciale pour déterminer si elles sont relatives ou absolues.
Le principe clé pour mettre en évidence des lignes entières dans Google Sheets est d’utiliser des colonnes absolues et des lignes relatives. Lorsque vous travaillez avec une seule cellule, la colonne est rendue absolue, tandis que la ligne reste relative.
Par exemple : $B5
Lorsque vous spécifiez une plage de cellules, la référence de la cellule de départ devient absolue, tandis que la référence de la cellule de fin devient absolue pour les colonnes et relative pour les lignes.
Par exemple : $A$3:$E11
Similaire : Comment mettre en valeur la valeur de résultat VLOOKUP dans Google Sheets
Maintenant que vous avez les secrets pour mettre en valeur des lignes entières dans Google Sheets, à vous de jouer ! Utilisez ces astuces pour rendre votre travail plus efficace et professionnel. Amusez-vous bien !
