Modèle de réservation de créneaux horaires par heure dans Google Sheets

Dans cet article, nous vous présenterons un modèle de réservation de créneaux horaires par heure dans Google Sheets, ainsi que les formules utilisées pour le créer.

Introduction

Imaginez pouvoir gérer facilement les réservations de voitures, de vélos, d’équipements, de tâches ou de locations de chambres à l’heure. Notre modèle de réservation de créneaux horaires par heure dans Google Sheets vous permet de le faire de manière simple et intuitive.

Explorez notre interface de réservation de créneaux horaires dynamique et intuitive

Notre modèle de réservation de créneaux horaires par heure dans Google Sheets se compose de deux feuilles : « Réservations » et « Statut ». Vous pouvez le prévisualiser et le copier en utilisant le lien de prévisualisation du modèle suivant.

Télécharger le modèle

Commençons par explorer la feuille « Statut ».

Feuille « Statut »

Commencez par entrer tous les éléments disponibles à la réservation dans la plage A4:A. Vous pouvez remplacer les éléments existants et en ajouter de nouveaux au besoin. Assurez-vous qu’il n’y ait pas de doublons.

La mise en évidence se fait comme suit dans la feuille « Statut » :

• Les cellules de couleur noire dans la grille représentent les créneaux horaires disponibles à la réservation.
• Les cellules avec une couleur orange représentent les réservations temporaires, tandis que les cellules vertes représentent les réservations confirmées.

Chaque cellule de la grille représente une heure, et le nom de la personne qui a réservé le créneau horaire apparaît dans la toute première cellule. Si une personne a réservé pendant 2 heures, la mise en évidence s’étendra sur deux cellules, et la première cellule contiendra son nom.

Il y a une raison spécifique pour afficher les noms des personnes dans notre modèle de réservation de créneaux horaires par heure. Sans les noms, il serait difficile d’identifier l’heure de début de la réservation de la deuxième personne, par exemple si une personne réserve de 10h00 à 12h00 et une autre de 12h00 à 18h00.

Vous pouvez sélectionner la date de début du statut en double-cliquant sur la cellule C1. Les barres dans la grille et la date/heure dans l’échelle de temps du graphique en haut se mettront à jour en conséquence. Le modèle est configuré pour afficher 7 jours à partir de la date sélectionnée, ce qui donne 168 (7×24) créneaux horaires dans chaque ligne pour chaque élément.

En résumé, entrez tous les éléments disponibles à la réservation dans les cellules A4:A et sélectionnez une date de début à partir de la cellule C1. Les formules se chargeront du reste.

Feuille « Réservations »

Il s’agit de la deuxième feuille de notre modèle de réservation de créneaux horaires par heure dans Google Sheets.

Les listes déroulantes dans la plage A3:A afficheront les éléments que vous avez saisis dans la plage A4:A de la feuille « Statut ». Assurez-vous donc de saisir tous les éléments disponibles à la réservation dans la plage A4:A de la feuille « Statut ».

Sélectionnez un élément dans la cellule A3. Saisissez le nom de la personne ayant réservé dans la cellule B3, suivi de l’heure de début de la réservation (horodatage) et de l’heure de fin (horodatage) dans les cellules C3:D3.

Rappelez-vous, notre modèle est conçu pour des réservations par heure, vous ne devez donc saisir que la composante heure dans le temps, en sautant les secondes et les minutes.

Ensuite, sélectionnez soit « Temporaire » soit « Confirmé » dans la cellule F3.

Répétez ce processus dans les lignes suivantes.

C’est tout ce que vous devez saisir dans la feuille « Réservations » de notre modèle de réservation de créneaux horaires par heure dans Google Sheets.

En respectant les points suivants lors de la saisie de données dans la feuille « Réservations », vous générerez des barres de statut correctes dans la feuille « Statut ».

• Les heures de début et de fin doivent être des horodatages.
• Les minutes et les secondes ne sont pas prises en charge dans les heures de début et de fin.
  • Si une personne réserve pendant 1 heure, cela devrait ressembler à ceci :
    • Début : 02/09/2023 14:00:00
    • Fin : 02/09/2023 15:00:00
  • Pas comme ceci :
    • Début : 02/09/2023 14:00:00
    • Fin : 02/09/2023 14:00:00.
• Avant de réserver, consultez la feuille « Statut » pour connaître les créneaux horaires disponibles afin d’éviter les erreurs telles que les dates qui se chevauchent pour la réservation du même élément.

Formules utilisées dans le modèle de réservation de créneaux horaires par heure dans Google Sheets

Je n’ai pas utilisé de scripts dans notre modèle. J’ai utilisé des fonctions natives de la feuille pour la mise en évidence et d’autres fins. Toutes les formules sont des formules matricielles, ce qui signifie qu’elles s’ajusteront automatiquement à mesure que vos données augmentent. Vous n’avez pas besoin de les copier-coller ou de les faire glisser.

Voici les formules utilisées dans notre modèle de réservation de créneaux horaires par heure dans Google Sheets.

Règles de mise en évidence

Il y a deux règles de format conditionnel dans la feuille « Statut » pour tracer les barres.

1. Réservation confirmée des créneaux horaires (vert)

La formule suivante est utilisée dans Format > Format conditionnel > Règle de formule personnalisée pour « Appliquer à la plage » C4:FN53 afin de tracer les barres de couleur verte qui représentent les réservations de créneaux horaires confirmées.

=LET( start_end, "Booking!C3:D", booked_item, "Booking!A3:A", status, "Booking!F3:F", item, $A4, datetime, C$3, ftr, FILTER(INDIRECT(start_end), (INDIRECT(booked_item)=item)* (INDIRECT(status)="Confirmé")), SUM( MAP(CHOOSECOLS(ftr, 1), INDEX(CHOOSECOLS(ftr, 2)-TIME(1, 0, 0), 0), LAMBDA(st, en, N(ISBETWEEN(datetime, st, en)))) ) )

Explication de la formule :

Nous avons utilisé la fonction LET pour définir des noms pour des plages, ce qui rend la formule plus lisible et plus efficace. Voici les noms définis et les expressions de valeur :

• start_end : « Booking!C3:D »
• booked_item : « Booking!A3:A »
• status : « Booking!F3:F »
• item : $A4
• datetime : C$3
• ftr : FILTER(INDIRECT(start_end), (INDIRECT(booked_item)=item)*(INDIRECT(status)= »Confirmé »))

L’expression de la formule est la suivante :

=SUM(MAP(CHOOSECOLS(ftr, 1), INDEX(CHOOSECOLS(ftr, 2)-TIME(1, 0, 0), 0), LAMBDA(st, en, N(ISBETWEEN(datetime, st, en)))) )

La fonction MAP teste si l’heure dans la cellule C3 de la feuille « Statut » se trouve entre les date/heure de début et de fin filtrées (ftr) dans chaque ligne, renvoyant un tableau de zéros et de uns. La fonction SUM totalise le résultat. Si celui-ci est supérieur à 0, le créneau horaire correspondant en dessous de C3 est mis en évidence.

Dans la formule, les références de cellules $A4 et C$3 utilisent une combinaison de références de cellules relatives et absolues.

Cette configuration permet de tester et de mettre en évidence chaque cellule de la grille de manière appropriée lorsque la formule est étendue à différentes cellules dans la feuille.

2. Réservation temporaire des créneaux horaires (orange)

Il s’agit essentiellement d’une copie de la formule ci-dessus. La seule différence réside dans la partie des critères de la fonction FILTER, où nous avons remplacé INDIRECT(status)= »Confirmé ») par INDIRECT(status)= »Temporaire »).

Formule pour afficher les noms dans la barre d’état

Une caractéristique distinctive de notre modèle de réservation de créneaux horaires par heure est l’affichage des noms des personnes ayant réservé sur les créneaux horaires dans la barre. Cette fonctionnalité facilite la distinction entre les réservations continues de créneaux horaires par différentes personnes.

Pour cela, la formule suivante est utilisée dans la cellule C4 de la feuille « Statut » :

=LET( datetime, C3:3, item, A4:A, name, Booking!$B$3:$B, r_item, Booking!$A$3:$A, start, Booking!$C$3:$C, MAP(datetime, LAMBDA(c, MAP(item, LAMBDA(r, JOIN(" ?", IFNA(FILTER(name, (r_item=r)*(start=c)))) )))) )

Explication de la formule :

Noms et expressions de valeur définis dans la fonction LET :

• datetime : C3:3
• item : A4:A
• name : Booking!$B$3:$B
• r_item : Booking!$A$3:$A
• start : Booking!$C$3:$C

L’expression de la formule est la suivante :

=MAP(datetime, LAMBDA(c, MAP(item, LAMBDA(r, JOIN(" ?", IFNA(FILTER(name, (r_item=r)*(start=c))))))))

La formule est facile à comprendre. La fonction FILTER filtre les noms des personnes ayant réservé à un moment précis (C3) et pour un élément spécifique (A4).

Pour couvrir chaque ligne (C3:3) et chaque colonne (A4:A), deux fonctions MAP sont utilisées.

Échelle de temps dynamique pour le modèle de réservation de créneaux horaires par heure

Dans la cellule C3 de la feuille « Statut », la formule suivante génère des dates et des heures pour le modèle de réservation de créneaux horaires par heure :

=ARRAYFORMULA(C1+SEQUENCE(1, 7*24, 0)/24)

J’ai formaté la plage C3:3 en « HH:MM » en utilisant Format > Nombre > Format de date et d’heure personnalisé.

La fonction SEQUENCE produit des nombres de 1 à 168. En divisant ces nombres par 24 et en ajoutant le résultat à la date de la cellule C1, nous obtenons les valeurs datetime souhaitées.

Formules facultatives dans le modèle de réservation de créneaux horaires par heure

Il y a deux formules facultatives : une dans la cellule C2 de la feuille « Statut » et une dans la cellule E2 de la feuille « Réservations ».

Formule dans C2 (feuille « Statut ») :

La formule affiche les dates pour chaque tranche de 24 heures dans l’échelle de temps.

=ArrayFormula(IF(MOD(C3:FN3, 1)=TIME(0, 0, 0), INT(C3:FN3),))

Explication :

• La fonction MOD, MOD(C3:FN3, 1), extrait la composante temps des valeurs datetime dans les cellules C3 à FN3. La fonction IF évalue les valeurs temps extraites et renvoie les dates correspondantes dans les cellules C3 à FN3 chaque fois que la fonction MOD retourne 00:00.

Formule dans E2 (feuille « Réservations ») :

Cette formule renvoie la durée entre l’heure de début et l’heure de fin de la réservation :

=ARRAYFORMULA(VSTACK("Durée", IF(A3:A="",,D3:D-C3:C)))

Explication :

• IF(A3:A= » »,,D3:D-C3:C) : Calcule la durée uniquement s’il y a une réservation (si A3:A n’est pas vide).
• VSTACK(« Durée », …) : VSTACK empile l’étiquette « Durée » au-dessus des durées calculées.

Conclusion

En conclusion, ce modèle convivial et efficace de réservation de créneaux horaires par heure dans Google Sheets simplifie la gestion des rendez-vous et des réservations.

Cette version est une extension de notre modèle de calendrier de réservation et de statut des réservations dans Google Sheets, conçu pour la gestion des réservations par jour.

Les deux modèles présentent une conception intuitive et des fonctionnalités automatisées, ce qui facilite la planification.

N’hésitez pas à personnaliser et à utiliser ce modèle de réservation de créneaux horaires par heure pour rationaliser votre gestion du temps, en garantissant une expérience de réservation fluide et organisée tant pour vous que pour vos clients.

Améliorez votre productivité et éliminez les tracas liés à la planification grâce à cet outil pratique à portée de main.