Il est essentiel d’apprendre comment trouver les dates les plus anciennes dans Google Sheets. Cette fonctionnalité est utile dans de nombreux secteurs, en particulier dans la logistique.
La date joue un rôle important dans tous les aspects de notre vie. Jetez un coup d’œil à l’image ci-dessous pour comprendre ce que signifie « trouver les dates les plus anciennes ».
Il existe de nombreux cas où vous pouvez avoir besoin de trouver les dates les plus anciennes. Si vous travaillez en tant que coordonnateur logistique, gérez les achats de matériel ou vendez des produits sur des plateformes en ligne, vous pouvez avoir besoin de cette fonctionnalité.
Par exemple, si vous avez commandé un article qui peut arriver en différents lots à des dates différentes, vous pouvez utiliser les astuces suivantes.
Il vous suffit de saisir le planning d’arrivée de tous ces articles et d’utiliser mes astuces pour trouver la date d’arrivée la plus ancienne. Ainsi, vous pourrez prendre les dispositions nécessaires pour recevoir le matériel.
Comment trouver les dates les plus anciennes dans Google Sheets ?
Inutile de parcourir manuellement toutes les dates d’une liste pour trouver les plus anciennes dans Google Sheets. Je vais vous faciliter la tâche en vous fournissant une formule Google Sheets pour résoudre ce problème courant.
Voici l’image à observer pour mieux comprendre ce que vous allez apprendre.
Lorsque vous avez différents articles (colonne A) et différentes dates de livraison (colonne B), vous pouvez utiliser une formule de tableau qui renvoie plusieurs dates les plus anciennes dans Google Sheets.
Si vous avez un seul article dans la colonne A et plusieurs dates de livraison, vous pouvez utiliser les fonctions MIN ou SMALL de Google Sheets. Vous pouvez suivre le lien ci-dessous pour en savoir plus sur ces astuces simples.
Find Minimum Value and Return Value from Another Column
Cependant, dans notre exemple ci-dessus, nous allons utiliser la fonction Vlookup dans une formule de tableau. Mais il y a une petite subtilité. La plage de recherche dans Vlookup sera une combinaison des formules SORT et SORTN.
Voici ma liste d’articles dans la colonne A et les dates de livraison possibles dans la colonne B. Grâce à ma formule, j’ai pu trouver les dates de livraison les plus anciennes pour chaque article dans la colonne F.
Formule pour trouver les dates les plus anciennes dans Google Sheets
Voici ma formule dans la cellule F2 de l’exemple ci-dessus :
=ArrayFormula(VLOOKUP(E2:E5,SORTN(SORT(A2:B9,2,TRUE,1,TRUE),20,2,1,TRUE),2,FALSE))
En réalité, la partie surlignée (cyan et vert pâle) de la formule suffit. Je l’expliquerai plus tard.
Cette formule pour trouver les dates les plus anciennes dans Google Sheets est une combinaison des formules SORT et SORTN. Cette combinaison agit comme une plage de recherche dans Vlookup.
Logique et explication de la formule
L’ordre de la formule est le suivant : SORT > SORTN > VLOOKUP. Cela signifie que vous devez d’abord apprendre à utiliser SORT, puis SORTN, suivi de Vlookup.
Permettez-moi de vous expliquer le rôle de chacune des fonctions mentionnées ci-dessus dans la formule pour trouver les dates les plus anciennes dans Google Sheets.
SORT
=SORT(A2:B9,2,TRUE,1,TRUE)
Syntaxe :
SORT(plage, colonne_tri, est_ordonne, [colonne_tri2, ...], [est_ordonne2, ...])
Ici, j’ai simplement trié nos données d’exemple, d’abord en fonction de la colonne 2 qui contient les dates par ordre croissant, puis en fonction de la colonne 1 qui est également en ordre croissant.
Lors de ce tri, toutes les dates les plus basses se retrouvent en haut de la ligne.
Maintenant, la prochaine étape consiste à supprimer les doublons dans la colonne 1. Pour cela, nous pouvons utiliser SORTN, une fonction de tri avancée dans Google Sheets.
Pour en savoir plus sur cette fonction, veuillez consulter mon Guide des fonctions Google Sheets.
SORTN
=SORTN(SORT(A2:B9,2,TRUE,1,TRUE),20,2,1,TRUE)
Syntaxe :
SORTN(plage, [n], [mode_affichage_ties], [colonne_tri], [est_ordonne], [colonne_tri2, ...], [est_ordonne2, ...])
Veuillez consulter la première capture d’écran ci-dessus. Vous pouvez y voir que les valeurs en double se trouvent dans la première colonne. Regardez maintenant les arguments utilisés dans la formule.
PLAGE :
SORT(A2:B9,2,TRUE,1,TRUE)
[N] = 20
C’est le nombre de lignes à renvoyer par la formule. J’ai simplement mis un nombre aléatoire dans cet exemple car je sais que le nombre de lignes renvoyées après la suppression des doublons sera inférieur à 20.
Lorsque vous avez un grand nombre de lignes et que vous n’êtes pas sûr des lignes, vous pouvez utiliser 9^9 au lieu de mettre 20 ou un autre nombre.
Remove Duplicates in Google Sheets
MODE_AFFICHAGE_TIES : Pour supprimer les doublons, vous devez utiliser le nombre 2 comme mode_affichage_ties dans SORTN (j’en détaille plus dans mon tutoriel pertinent sur SORTN).
COLONNE_TRI : C’est la colonne à trier. Cela signifie que vous devez mettre le numéro de colonne qui contient les doublons et ici c’est la colonne 1.
Voici le résultat.
En réalité, cette formule est suffisante pour trouver les dates les plus anciennes dans Google Sheets dans une liste d’articles. La partie Vlookup de notre formule principale est facultative.
VLOOKUP
Si vous souhaitez trouver la livraison la plus ancienne des articles « de votre choix », vous pouvez utiliser Vlookup sur le résultat précédent.
La formule SORTN ci-dessus renvoie tous les articles et leurs dates de livraison les plus anciennes.
Tout d’abord, dans une colonne, saisissez les noms des articles pour lesquels vous souhaitez obtenir les dates de livraison les plus anciennes.
J’utilise tous les articles ici. J’ai donc utilisé une formule Unique pour obtenir les articles uniques dans la colonne E.
Voici notre formule principale que j’ai déjà partagée au début de ce tutoriel.
=ArrayFormula(VLOOKUP(E2:E5,SORTN(SORT(A2:B9,2,TRUE,1,TRUE),20,2,1,TRUE),2,FALSE))
Consultez la syntaxe Vlookup.
VLOOKUP(lookup_key, range, index, [is_sorted])
Dans cette formule, la clé de recherche se trouve dans la plage E2:E5. La plage est remplacée par la plage de combinaison SORTN+SORT ci-dessus. Lorsque vous devez rechercher plusieurs clés de recherche dans Vlookup, vous devez utiliser ArrayFormula dans Vlookup.
How to Use Vlookup to Return An Array Result in Google Sheets
C’est tout. Voici la méthode la plus facile pour trouver les dates les plus anciennes dans Google Sheets pour une liste d’articles.
