Est-il possible d’inclure plusieurs colonnes de somme dans la fonction SUMIF de Google Sheets ?
En général, cela n’est pas possible. Mais j’ai une astuce pour utiliser plusieurs colonnes de somme dans la fonction SUMIF. Elle fonctionne également avec un tableau.
Lorsque vous essayez d’inclure plusieurs colonnes de somme dans la fonction SUMIF de Google Sheets, vous obtiendrez soit une erreur #N/A, soit la somme de la première colonne uniquement.
Voyons un exemple :
Données d’exemple :
| Description | Jan | Feb |
|-------------|-----|-----|
| Lemon | 200 | 400 |
| Orange | 300 | 600 |
| Lemon | 100 | 300 |La formule suivante renverrait 600, c’est-à-dire le total des « Lemon » de la colonne B (pour en savoir plus sur la fonction SUMIF, veuillez consulter mon guide sur les fonctions de Google Sheets) :
=SUMIF(A2:A5, "Lemon", B2:C5)Si vous utilisez la formule suivante, vous verrez une erreur #N/A en raison du nombre incorrect d’arguments utilisés :
=SUMIF(A2:A5, "Lemon", B2:B5, C2:C5)Cela signifie que la fonction SUMIF ne peut normalement gérer qu’une seule plage de somme. Mais il existe une astuce astucieuse pour contourner cette limitation.
Comment inclure plusieurs colonnes de somme dans la fonction SUMIF de Google Sheets
Voici l’astuce pour inclure plusieurs colonnes de somme dans la fonction SUMIF de Google Sheets. À ma connaissance, cela ne fonctionne pas dans Excel.
Syntaxe : SUMIF(plage, critère, [plage_somme])
Étapes :
- Trouvez le nombre de colonnes à additionner.
- Dupliquez le paramètre « plage » selon le nombre de colonnes de somme. S’il y a 2 colonnes, faites deux fois la duplication de la plage (Syntaxe – {plage, plage, …}).
- Ensuite, utilisez plusieurs colonnes de somme comme plage_somme.
Exemple :
Selon nos données ci-dessus sur les « fruits », la plage est A2:A5 et le nombre de colonnes à additionner est de deux. Nous devons donc dupliquer la plage A2:A5 deux fois. Comment ?
Voici comment faire :
{A2:A5, A2:A5}Maintenant, voyez la formule SUMIF :
=SUMIF({A2:A5, A2:A5}, "Lemon", B2:C5)Cela renverrait 900 en tant que résultat.
Oui ! Ce qui précède est l’astuce intelligente pour inclure deux colonnes de somme dans la fonction SUMIF de Google Sheets. Cela fonctionnera également avec la formule Array (critères multiples) Sumif.
Exemple :
=ArrayFormula(SUMIF({A2:A5, A2:A5}, {"Lemon"; "Avocado"}, B2:C5))Si une autre colonne existe, par exemple, la colonne D, la formule serait :
=SUMIF({A2:A5, A2:A5, A2:A5}, "Lemon", B2:D5)Si plusieurs colonnes de somme sont présentes dans la plage_somme de la fonction SUMIF, il ne sera pas pratique de dupliquer la plage. Dans ce cas, nous pouvons simplifier la formule comme suit.
Je réécris la formule précédente avec une formule de plage dynamique.
=ArrayFormula(SUMIF(if(len(B2:D5)>=0, A2:A5), "Lemon", B2:D5))plage : if(len(B2:D5)>=0, A2:A5)
critère : « Lemon »
plage_somme : B2:D5
Il existe également plusieurs astuces/alternatives intelligentes. Pour en savoir plus, utilisons les données d’exemple de la capture d’écran ci-dessous (uniquement les 3 premières colonnes).
Astuces de contournement impliquant Sumif
Sur l’image, vous pouvez voir les résultats de cinq formules dans les cellules D2:H2 et les descriptions des formules dans les cellules D1:H1.
Les cinq formules additionnent les colonnes B et C si le nom des jours de la semaine dans la colonne A est « Sun ». Cela signifie que le critère est « Sun ».
Si vous êtes un utilisateur basique de Google Sheets et que vous souhaitez uniquement utiliser SUMIF, vous pouvez suivre la solution basée sur la colonne d’aide ci-dessous. Elle vous sera facile à comprendre.
Il est facile d’utiliser SUMIF avec une colonne d’aide pour inclure plusieurs colonnes de somme.
Commençons par la solution utilisant la colonne d’aide en premier. Ensuite, vous pouvez voir les cinq autres formules différentes. Choisissez celle qui vous convient le mieux.
Sumif avec une colonne d’aide
Exemple :
=SUMIF(A2:A13, "Sun", D2:D13)J’ai utilisé la colonne D, qui est la colonne d’aide, en tant que plage_somme dans SUMIF. La colonne D contient le total des colonnes B et C.
Je sais que la plupart d’entre vous n’aiment pas utiliser de colonne d’aide. Je n’utilise moi-même que très rarement des colonnes d’aide. Voici donc une solution de contournement utilisant deux formules SUMIF.
En ajoutant les résultats de plusieurs formules SUMIF
Je ne pense pas que vous ayez besoin d’explication supplémentaire. Dans l’exemple ci-dessous, la première formule SUMIF additionne la colonne B. La deuxième formule additionne la colonne C.
Formule :
=SUMIF(A2:A13, "Sun", B2:B13) + SUMIF(A2:A13, "Sun", C2:C13)Formules alternatives à SUMIF avec plusieurs colonnes de somme
Voici les formules alternatives les plus utiles au cas où vous souhaiteriez utiliser plusieurs colonnes de somme dans SUMIF de Google Sheets.
Alternative SUM et IF Statement à Sumif avec plusieurs colonnes de somme
Oui ! cette fois-ci, j’utilise la fonction SUM et l’instruction IF pour remplacer SUMIF. C’est l’une des formules les plus utilisées dans Excel.
=ArrayFormula(SUM(IF(A2:A13="Sun", B2:B13+C2:C13)))Alternative Query à SUMIF avec plusieurs colonnes de somme dans Google Sheets
Comme je l’ai dit plusieurs fois dans le passé, Query est l’une des meilleures fonctions dans Google Sheets. Vous pouvez utiliser Query comme substitut à de nombreuses autres fonctions dans Google Sheets.
Voyez comment Query remplace SUMIF dans ce cas. C’est l’une des solutions élégantes.
=SUM(QUERY(A1:C, "Select B+C where A = 'Sun'"))Combinaison filtrer et sommer
C’est l’une des meilleures et aussi ma recommandation pour utiliser une alternative à Sumif avec plusieurs colonnes de somme dans Google Sheets.
Formule :
=SUM(FILTER(B2:C13, A2:A13="Sun"))La formule ci-dessus utilise la fonction Filter pour filtrer les colonnes B et C (plage_somme) en fonction du critère, c’est-à-dire « Sun », puis additionne les colonnes.
Maintenant, voici la solution finale.
Sumproduct
Je sais que de nombreux utilisateurs de Google Sheets utilisent fréquemment SUMPRODUCT pour remplacer SUMIF/SUMIFS.
La raison est que SUMPRODUCT peut rendre vos formules plus courtes, plus intelligentes et plus faciles à lire. Voyez celle-ci !
Formule :
=SUMPRODUCT(B2:C*(A2:A="Sun"))J’ai présenté ci-dessus quelques options de formule pour que vous puissiez utiliser lorsque vous souhaitez utiliser plusieurs colonnes de somme dans SUMIF de Google Sheets.
Laquelle préférez-vous ? J’aimerais connaître votre avis dans les commentaires ci-dessous. Amusez-vous bien !
Articles connexes :
- Comment utiliser SUMIFS pour additionner plusieurs colonnes dans Google Sheets
- Comment utiliser la fonction Sumif horizontalement dans Google Sheets
- Somme des lignes ou des colonnes de la matrice en utilisant SUMIF dans Google Sheets
