Dans Google Sheets, la fonction Query est idéale pour résumer des données, qu’il s’agisse de texte, de chiffres ou de dates. Pour créer un résumé quotidien/hebdomadaire/mensuel/trimestriel/annuel, Query est sans aucun doute le meilleur choix.
Toute entreprise, en particulier les ventes, nécessite des transactions quotidiennes. Peu importe le type d’activité, vous avez probablement des données à enregistrer quotidiennement, que ce soit des ventes, des achats ou des transactions en espèces. Même pour un blogueur, le trafic du site, le nombre de pages vues, le taux de clics, etc., doivent être enregistrés quotidiennement.
Si tel est le cas, vous voudrez peut-être résumer vos transactions quotidiennes. Voici quelques exemples de la façon de créer un résumé quotidien/hebdomadaire/mensuel/trimestriel/annuel dans Google Sheets à l’aide de la fonction Query. Vous pouvez utiliser mes formules telles quelles en ajustant les colonnes de votre rapport de ventes/achats selon le format de mon rapport. J’ai inclus dans ce tutoriel ma feuille contenant les formules et les données de démonstration.
La fonction Query pour créer un résumé quotidien/hebdomadaire/mensuel/trimestriel/annuel
Dans Query, vous pouvez utiliser les fonctions scalaires suivantes pour créer un rapport récapitulatif basé sur une colonne de dates. Dans ce contexte, la colonne de dates fait référence à une colonne contenant les dates des transactions.
- month()
- quarter()
- year()
Est-ce que ces trois fonctions scalaires sont suffisantes pour créer un résumé quotidien/hebdomadaire/mensuel/trimestriel/annuel ?
Je sais que ce que nous voulons, c’est une formule Query pour créer un résumé quotidien/hebdomadaire/mensuel/trimestriel/annuel. Il existe cinq types de résumés basés sur les colonnes de dates. Cependant, pour le rapport quotidien, la clause de regroupement Query est suffisante. Pour le résumé hebdomadaire, nous devons utiliser une fonction de date autre que Query. Vous pouvez voir cela dans les exemples de formules ci-dessous.
Query pour créer un rapport quotidien dans Google Sheets
Voici un exemple de données de ventes simulées à partir desquelles je vais créer un résumé quotidien du rapport de ventes.
Note: Consultez mon guide des fonctions Google Sheets pour apprendre Query et d’autres fonctions populaires.
Formule: Résumé quotidien des ventes impliquant les colonnes Date et Quantité totale.
=QUERY(A1:F8,"Select A, sum(F) where A is not null group by A")
La formule ci-dessus est dans la cellule I1. Certains d’entre vous souhaiteront peut-être inclure le nom du produit dans le résumé. Voici une formule Query que vous pouvez utiliser :
Formule: Résumé quotidien des ventes impliquant les colonnes Date, Produit et Quantité totale.
=QUERY(A1:F8,"Select A,C, sum(F) where A is not null group by A,C")
Vous obtiendrez un rapport de résumé quotidien par date et par produit.
Query pour créer des rapports mensuels dans Google Sheets
Dans les formules pour créer des rapports quotidiens/hebdomadaires/mensuels/trimestriels/annuels, à l’exception du rapport hebdomadaire, toutes les formules sont presque identiques. Je vais donc détailler la formule Query pour créer le rapport hebdomadaire à la dernière partie.
Formule: Résumé mensuel des ventes impliquant les colonnes Date et Quantité.
La différence réside dans l’utilisation de la fonction scalaire month(). J’ai souligné cette différence dans la capture d’écran ci-dessus.
=QUERY(A1:F8,"Select month(A)+1, sum(F) where A is not null group by month(A)+1")
Conseil : La fonction scalaire month() renvoie 0 pour janvier et 11 pour décembre. Vous devez donc ajouter +1 à cette fonction pour obtenir 1 pour janvier, 2 pour février, et ainsi de suite.
Formule: Résumé mensuel des ventes impliquant les colonnes Date, Produit et Quantité.
Il va de soi que j’utilise également la fonction scalaire month() ici.
=QUERY(A1:F8,"Select month(A)+1,C, sum(F) where A is not null group by month(A)+1,C")
Query pour créer des rapports annuels dans Google Sheets
Comme je vous l’ai expliqué, la Query pour créer des rapports quotidiens/hebdomadaires/mensuels/trimestriels/annuels dans Google Sheets est similaire. Ici, la fonction scalaire year() fait la différence.
Formule: Résumé annuel des ventes impliquant les colonnes Date et Quantité.
=QUERY(A1:F8,"Select year(A), sum(F) where A is not null group by year(A)")
Formule: Résumé annuel des ventes impliquant les colonnes Date, Produit et Quantité.
=QUERY(A1:F8,"Select year(A),C, sum(F) where A is not null group by year(A),C")
Query pour créer des rapports trimestriels dans Google Sheets
Remplacez la fonction scalaire year() par quarter() dans Query pour créer un résumé trimestriel du rapport de ventes.
Formule: Résumé trimestriel des ventes impliquant les colonnes Date et Quantité.
=QUERY(A1:F8,"Select quarter(A), sum(F) where A is not null group by quarter(A)")
Formule: Résumé trimestriel des ventes impliquant les colonnes Date, Produit et Quantité.
=QUERY(A1:F8,"Select year(A),C, sum(F) where A is not null group by year(A),C")
Query pour créer des rapports hebdomadaires dans Google Sheets
Il n’y a pas de fonction scalaire weeknum() à utiliser ici, ce qui rend les deux formules suivantes un peu plus complexes. Nous devons utiliser une fonction de date spécifique à Google Sheets appelée WEEKNUM avec Query.
Cette fonction renvoie des numéros de semaine uniques pour chaque semaine. Par exemple, le numéro de semaine du 17/10/2018 est 42 et celui du 23/10/2018 est 43.
Vous pouvez tester cela en utilisant la formule =weeknum(« 14/10/2018 »). Voici comment j’utilise la fonction WEEKNUM dans Query.
Formule: Résumé hebdomadaire des ventes impliquant les colonnes Date et Quantité.
=query({ArrayFormula(if(len(A2:A),(WEEKNUM(A2:A)),)),query(B2:G)},"Select Col1,Sum(Col6) where Col1>0 group by Col1")
Formule: Résumé hebdomadaire des ventes impliquant les colonnes Date, Produit et Quantité.
=query({ArrayFormula(if(len(A2:A),(WEEKNUM(A2:A)),)),query(B2:G)},"Select Col1,Col3, Sum(Col6) where Col1>0 group by Col1,Col3")
Je sais que vous avez besoin d’un tutoriel détaillé pour le rapport hebdomadaire. Vous pouvez suivre ce tutoriel Google Sheets – Comment créer un rapport hebdomadaire dans Google Sheets.
Feuille de modèle
Conseils/ressources supplémentaires pour créer des résumés quotidiens/hebdomadaires/mensuels/trimestriels/annuels dans Google Sheets
- Filtrer par mois et année dans Query dans Google Sheets.
- Regroupement par mois, trimestre, année dans un tableau croisé dynamique dans Google Sheets.
- Comment regrouper les données par mois et année dans Google Sheets.
- Google Sheets Query : Comment convertir un mois en numéro en nom de mois en texte.
