Si vous suivez la méthode standard pour effectuer une recherche Vlookup sur chaque colonne alternative, vous risquez de passer beaucoup de temps à coder la formule. Le temps passé sur de telles formules dépend du nombre de colonnes dans la plage. Si vous avez trois colonnes pour rechercher une clé, vous devrez écrire trois formules Vlookup. Ce n’est pas une tâche simple dans Google Sheets lorsque vous avez plusieurs colonnes à rechercher, n’est-ce pas? Il y a des chances de se tromper dans les plages de la formule.
Voyons comment utiliser correctement Vlookup pour rechercher chaque colonne alternative et renvoyer les valeurs des colonnes correspondantes dans les lignes trouvées.
Supposons que la clé de recherche soit la lettre « a » et que vous souhaitiez la rechercher dans les colonnes B, D et F et renvoyer les valeurs des colonnes C, E et G.
Habituellement, vous pourriez écrire trois formules avec les plages B1:C, D1:E et F1:G. Simplifions cela.
Deux façons faciles de Vlookup sur chaque colonne alternative dans Google Sheets
Je vous présente deux approches pour effectuer une recherche Vlookup sur chaque colonne alternative dans Google Sheets. Les deux sont faciles à suivre. La première est une formule de copie-coller sans tableau, tandis que la seconde est une formule de tableau.
Voici!
Vlookup sur chaque colonne alternative dans Google Sheets
Dans l’exemple ci-dessus, j’ai utilisé la formule suivante dans la cellule J2, que j’ai ensuite glissée vers la droite et vers le bas.
=vlookup($I2,{index(B$2:$G$7,0,column(A$1)),index(B$2:$G$7,0,column(B$1))},2,0)
Lorsque vous écrivez une telle formule pour effectuer une recherche Vlookup sur chaque colonne alternative, vous devez utiliser attentivement les signes de dollar pour rendre les références de cellules/plages relatives ou absolues. Veuillez lire cela sous l’explication de la formule ci-dessous.
Explication de la formule
Syntaxe : VLOOKUP(clé_de_recherche, plage, index, [trié])
-
clé_de_recherche – $I2
-
Dans cette clé_de_recherche, nous avons utilisé une colonne absolue et une ligne relative dans la référence.
-
Ainsi, rien ne se passe lorsque nous glissons la formule vers la droite, mais la ligne change lorsque nous la collons vers le bas.
-
plage – {index(B$2:$G$7,0,column(A$1)),index(B$2:$G$7,0,column(B$1))}
-
La plage « dynamique » ci-dessus est la partie clé de Vlookup sur chaque colonne alternative dans Google Sheets.
-
Nous avons utilisé deux formules INDEX pour obtenir les colonnes correctes lorsque nous glissons la formule Vlookup dans ses cellules adjacentes.
Syntaxe : INDEX(référence, [ligne], [colonne])
-
référence – B$2:$G$7 (la colonne B s’ajuste lorsque nous copions vers la droite).
-
ligne – 0
-
colonne – Nous avons utilisé la formule column(A$1) dans le premier INDEX et column(B$1) dans le second INDEX.
-
Ils sont égaux à 1 et 2, respectivement.
-
Le 0 (zéro) représente tout, 1 signifie le 1er, 2 signifie le 2e, et ainsi de suite.
-
Ainsi, le premier INDEX renvoie toutes les lignes de la 1re colonne, tandis que le second INDEX renvoie toutes les lignes de la 2e colonne.
-
Lorsque nous glissons ou copions la formule une fois vers la droite, la première formule d’index renvoie la deuxième colonne et la deuxième formule renvoie la 3e colonne.
-
C’est correct, n’est-ce pas?
-
Oui! Notez que B$2:$G$7 devient également C$2:$G$7, donc le modèle ci-dessus est OK.
-
index (numéro de colonne de sortie Vlookup) – 2
Vlookup sur chaque colonne alternative en aplatisant les colonnes
Vous voulez une formule de tableau pour rechercher chaque colonne alternative ? Codons cela ci-dessous.
Tout d’abord, nous devons ajouter des étiquettes de champ au tableau. Il est essentiel d’identifier les colonnes dans Vlookup.
J’ai ajouté les étiquettes dans B1:G1 pour le tableau de recherche dans B2:G7. Veuillez prêter une attention particulière aux étiquettes en haut du tableau de sortie (J1:L1).
Cette fois-ci, il vous suffit d’entrer la formule dans la cellule J2 pour effectuer une recherche Vlookup sur chaque colonne alternative dans Google Sheets.
Pour éviter toute confusion, je code la formule étape par étape.
Étapes
Récemment, j’ai partagé une formule pour aplatir chaque colonne alternative dans Google Sheets. Nous l’utiliserons ici.
Formule n°1 (Aplatir les listes) : =ArrayFormula(FLATTEN(filter(B1:G1,iseven(column(B1:G1))=TRUE)&"|"&filter(B2:G7,ISEVEN(column(B1:G1))=TRUE)))
Formule n°2 (Aplatir les prix) : =FLATTEN(filter(B2:G7,ISODD(column(B1:G1))=TRUE))
Pour le moment, j’ai inséré les formules ci-dessus dans les cellules I6 et J6, respectivement.
Voyons comment les utiliser pour effectuer une recherche Vlookup sur chaque colonne alternative.
Dans la cellule J2, insérez cette formule Vlookup.
Formule n°3 : =ArrayFormula(vlookup(J1:L1&"|"&I2:I3,I6:J23,2,0))
Maintenant, nous pouvons combiner les trois formules ci-dessus dans la cellule J2 selon la syntaxe suivante :
=ArrayFormula(vlookup(J1:L1&"|"&I2:I3,{formule_1,formule_2},2,0))
Et voilà !
=ArrayFormula(vlookup(J1:L1&"|"&I2:I3,{FLATTEN(filter(B1:G1,iseven(column(B1:G1))=TRUE)&"|"&filter(B2:G7,ISEVEN(column(B1:G1))=TRUE)),FLATTEN(filter(B2:G7,ISODD(column(B1:G1))=TRUE))},2,0))
De cette manière, nous pouvons effectuer une recherche Vlookup sur chaque colonne alternative dans Google Sheets.
Merci de vous être arrêté. Profitez-en !
Related:
