Một mẫu xem lịch trong Google Sheets có thể giúp bạn xem dữ liệu (hồ sơ) của mình một cách dễ hiểu.
Trong Google Sheets, chúng ta có thể tạo và xem báo cáo dưới dạng bảng sử dụng các chức năng như FILTER, QUERY hoặc Pivot Table.
Tuy nhiên, chế độ xem lịch tùy chỉnh trong Google Sheets hiển thị thông tin theo định dạng lịch chuẩn dựa trên tháng và năm được chọn bởi người dùng và các cài đặt khác trong bảng dữ liệu nguồn.
Bạn có thể di chuyển qua lịch theo tháng và năm.
Dữ liệu tương ứng sẽ được hiển thị dưới mỗi ngày trong tháng và năm được chọn, tùy thuộc vào sự có sẵn của dữ liệu trong bảng nguồn.
Bạn có thể sử dụng mẫu xem lịch của tôi trong Google Sheets để xem dữ liệu bán hàng, dữ liệu mua hàng, dữ liệu chấm công nhân viên, danh sách công việc, theo dõi sự kiện và cuộc họp, và nhiều hơn nữa.
Tính năng
Mẫu xem lịch tùy chỉnh trong Google Sheets hỗ trợ các loại dữ liệu khác nhau. Chúng bao gồm văn bản, số, thời gian và thời lượng.
Nếu có nhiều hồ sơ cho cùng một ngày, dữ liệu sẽ được tổng hợp dựa trên loại dữ liệu.
Số và thời lượng sẽ được tổng hợp (cộng dồn). Văn bản sẽ được làm duy nhất và sau đó được nối lại.
Kết hợp nhiều cột cũng được hỗ trợ.
Điều này hữu ích khi bạn nhập địa chỉ trong các cột, chẳng hạn như tên, email, số điện thoại, v.v., trong các cột riêng biệt của chúng.
Chúng ta sẽ tìm hiểu thêm về các tính năng trên ở phần ví dụ dưới đây. Trước đó, bạn có thể tải xuống (tạo bản sao của) mẫu xem lịch của tôi dưới đây.
C_V_Template
Sử dụng mẫu xem lịch tùy chỉnh trong Google Sheets
Tệp mẫu có hai bảng: Master và CV.
Bảng Master chứa chín trường (cột) được thiết lập sẵn:
- Cột 1: Ngày
- Các cột 2 đến 6: Văn bản
- Các cột 7 và 8: Thời gian
- Cột 9: Thời lượng hoặc số
Chúng ta chỉ điền dữ liệu vào các cột cần thiết. Bảng CV sẽ tự động cập nhật để phản ánh dữ liệu trong bảng Master.
Lưu ý: Giá trị được nhập vào các cột 2 đến 6 sẽ được kết hợp thành một giá trị duy nhất trong giao diện xem lịch.
Hãy xem ba ví dụ.
1. Xem lịch thời gian hàng ngày của một nhân viên
Giống như đã nêu ở trên, bảng Master được định dạng để hỗ trợ các loại dữ liệu khác nhau. Chúng ta sẽ bắt đầu bằng việc nhập dữ liệu chấm công của một nhân viên.
Để tạo lịch thời gian hàng ngày của một nhân viên, chúng ta cần ba trường dữ liệu: Ngày, Thời gian bắt đầu và Thời gian kết thúc.
Chúng ta sẽ điền dữ liệu vào các cột A, G và H, tương ứng với các cột 1, 7 và 8.
Xóa nhãn trường trong các cột chưa sử dụng B1:F1 và I1.
Dưới đây là giao diện xem lịch thời gian đến và đi của nhân viên mà chúng ta đã nhập vào bảng Master.
Ghi chú:
- Nếu một nhân viên có nhiều hồ sơ (đi vào và đi ra) cho cùng một ngày, thời gian sớm nhất sẽ được coi là thời gian vào và thời gian muộn nhất sẽ được coi là thời gian ra.
- Bạn nên nhập “Bắt đầu” và “Kết thúc” bằng cách thủ công vào cột A trong bảng CV, trong các hàng tương ứng. Vui lòng tham khảo hình ảnh phía trên.
2. Xem lịch hẹn trong Google Sheets
Trong ví dụ này, dữ liệu cần được xem trong giao diện lịch là một bảng nhật ký cuộc hẹn trong Google Sheets. Do đó, đầu vào mong muốn sẽ bao gồm các trường (cột) sau:
- Ngày (Cột 1)
- Tên (Cột 2)
- Email (Cột 3)
- Điện thoại (Cột 4)
- Địa điểm họp (Cột 5)
- Người tham dự (Cột 6)
- Thời gian (Cột 7)
Dưới đây là cách điền thông tin liên quan vào bảng Master:
3. Danh sách công việc theo lịch trong Google Sheets
Việc có một danh sách công việc là một cách tốt để ưu tiên các nhiệm vụ cá nhân hoặc liên quan đến công việc của bạn.
Nếu bạn đã duy trì hoặc đang có kế hoạch duy trì một bảng tính cho danh sách công việc, việc sử dụng Google Sheets là một ý tưởng tốt.
Bạn có thể sử dụng mẫu của tôi để nhập danh sách công việc của bạn và xem chúng dưới dạng lịch.
Dưới đây là các bước để sử dụng mẫu xem lịch công việc trong Google Sheets:
- Trong bảng Master, nhập các ngày công việc vào cột A và các công việc vào cột B.
- Chuyển đến bảng CV và chọn tháng trong ô G1 và năm trong ô H1.
- Danh sách công việc sẽ sẵn sàng để xem.
Mẫu Xem Lịch Trong Google Sheets: Công Thức Quan Trọng
Chúng ta có một số công thức mảng trong bảng CV. Chúng nằm trong phạm vi B5:B34. Một phần trong số đó được sử dụng để điền vào lịch động và các công thức đó nằm trong các ô B5, B10, B15, B20, B25 và B30.
Giữa các ô này, chúng ta có các công thức để truy xuất các giá trị cho xem lịch và đây là các công thức quan trọng đó.
B6: Công thức sau trong ô B6 truy xuất các giá trị văn bản từ cột B đến F (2 đến 6) từ bảng Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,source_txt,Master!$B$2:$F,header,Master!$B$1:$F$1,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,TEXTJOIN(CHAR(10),TRUE,UNIQUE(IFNA(FILTER(IF(LEN(source_txt),header&": "&source_txt,),DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))))))
Nó sẽ làm duy nhất và kết hợp văn bản.
B7: Công thức sau trong ô B7 truy xuất các giá trị thời gian từ cột G (7) từ bảng Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$G$2:$G,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))))))))
Nó sẽ trả về thời gian sớm nhất khi có nhiều mục nhập cho cùng một ngày.
B8: Công thức sau trong ô B8 truy xuất các giá trị thời gian từ cột H (8) từ bảng Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$H$2:$H,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))),1,0,1,0)))))
Nó sẽ trả về thời gian muộn nhất khi có nhiều mục nhập cho cùng một ngày.
B9: Công thức sau trong ô B9 truy xuất các giá trị thời lượng hoặc số từ cột I (9) từ bảng Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$I$2:$I,month_txt,$G$1,calendar_dt,B5:H5,result,MAP(calendar_dt,LAMBDA(dtd,IFNA(SUM(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))),IF(result>0,result,)))
Nó sẽ trả về giá trị tổng hợp (tổng) khi có nhiều mục nhập cho cùng một ngày.
Sao chép các công thức trên từ ô B6 đến B9 và dán chúng vào các ô B11, B16, B21, B26 và B31.
Kết luận
Tôi đã đưa ra ba ví dụ để chỉ cho bạn cách sử dụng mẫu xem lịch của tôi trong Google Sheets.
Bạn có thể nhận thấy rằng không có ví dụ nào sử dụng cột dữ liệu thứ 9 (I) trong bảng Master. Đây là cách sử dụng nó.
Giả sử bạn muốn hiển thị các chi phí hàng ngày của mình trong giao diện xem lịch.
Nhập ngày vào cột A, tiêu đề chi phí (mô tả) vào cột B và số tiền vào cột I. Nếu có nhiều chi phí trong cùng một ngày, bạn có thể xử lý chúng theo hai cách:
- Nhập chúng thành hai hàng (giả sử có hai chi phí). Điều này sẽ tạo ra hai bản ghi trong cùng một ngày. Công thức tương ứng sẽ kết hợp (tổng hợp) chúng.
- Nhập chúng thành một hàng. Nhập các mô tả cách nhau bằng dấu phẩy và thủ công cộng tổng các chi phí và nhập tổng vào cột I.
Tương tự, bạn có thể sử dụng cột thứ 9 để nhập thời lượng, chẳng hạn như làm thêm giờ. Bạn có thể thực hiện điều này sau khi đã thực hiện ba ví dụ trên.
Đó là tất cả về mẫu xem lịch trong Google Sheets. Hy vọng bạn đã thích nó.
