Một mẫu xem lịch trên Google Sheets có thể giúp bạn xem dữ liệu của mình một cách dễ hiểu. Trong Google Sheets, chúng ta có thể tạo và xem báo cáo dưới dạng bảng bằng cách sử dụng các chức năng như FILTER, QUERY, hoặc Pivot Table. Tuy nhiên, chế độ xem lịch tùy chỉnh trên Google Sheets hiển thị thông tin dưới dạng lịch chuẩn dựa trên tháng và năm được chọn bởi người dùng, cùng với các thiết lập khác trong bảng nguồn dữ liệu.
Bạn có thể dễ dàng điều hướng qua các tháng và năm trên lịch. Dữ liệu tương ứng sẽ được hiển thị dưới mỗi ngày trong tháng và năm được chọn, tùy thuộc vào sự có sẵn của dữ liệu trong bảng nguồn.
Bạn có thể sử dụng mẫu xem lịch trên Google Sheets của tôi để xem dữ liệu bán hàng, dữ liệu mua hàng, dữ liệu khách hàng, danh sách công việc, theo dõi sự kiện và cuộc họp, và nhiều hơn nữa.
Đặc điểm
Mẫu xem lịch tùy chỉnh trên Google Sheets hỗ trợ các loại dữ liệu khác nhau, bao gồm văn bản, số, thời gian và thời lượng. Nếu có nhiều bản ghi cho cùng một ngày, dữ liệu sẽ được tổng hợp dựa trên loại dữ liệu.
Số và thời lượng sẽ được tổng hợp (tổng cộng). Văn bản sẽ được làm duy nhất và sau đó được nối lại. Việc kết hợp nhiều cột cũng được hỗ trợ. Điều này hữu ích khi bạn có địa chỉ được nhập vào các cột riêng biệt như tên, email, số điện thoại, v.v.
Chúng ta sẽ tìm hiểu thêm về các tính năng trên trong phần ví dụ dưới đây. Trước đó, bạn có thể tải xuống (tạo bản sao) mẫu xem lịch của tôi ở dưới đây.
Sử dụng mẫu xem lịch tùy chỉnh trên Google Sheets
Tệp mẫu bao gồm hai sheet: Master và CV. Sheet Master chứa chín trường (cột) được thiết lập sẵn:
- Cột 1: Ngày
- Cột 2-6: Văn bản
- Cột 7 và 8: Thời gian
- Cột 9: Thời lượng hoặc số
Chúng ta chỉ cần điền dữ liệu vào các cột cần thiết. Sheet CV sẽ tự động cập nhật để phản ánh dữ liệu trong sheet Master.
Lưu ý: Các giá trị nhập trong các cột 2-6 sẽ được kết hợp thành một giá trị duy nhất trong lịch xem.
Hãy xem ba ví dụ sau.
1. Xem lịch thời gian hàng ngày của một nhân viên
Như chúng ta đã thấy ở trên, sheet Master được định dạng để hỗ trợ các loại dữ liệu khác nhau. Chúng ta sẽ bắt đầu bằng việc nhập dữ liệu về giờ punch của một nhân viên.
Để xem lịch thời gian hàng ngày của một nhân viên, chúng ta cần ba trường: Ngày, Giờ bắt đầu và Giờ kết thúc. Chúng ta sẽ điền dữ liệu vào các cột A, G và H, tương ứng với các cột 1, 7 và 8.
Xóa các nhãn trường trong các cột chưa sử dụng B1:F1 và I1.
Đây là lịch xem thời gian đăng nhập/đăng xuất của nhân viên mà chúng ta đã nhập vào sheet Master.
Ghi chú:
- Nếu một nhân viên có nhiều bản ghi (đăng nhập/đăng xuất) cho cùng một ngày, thời gian sớm nhất sẽ được coi là thời gian đăng nhập và thời gian muộn nhất sẽ được coi là thời gian đăng xuất.
- Bạn nên nhập thủ công văn bản “Bắt đầu” và “Kết thúc” vào cột A trên sheet CV, tại các hàng tương ứng. Vui lòng xem hình ảnh ở trên.
2. Xem lịch hẹn trong Google Sheets
Trong ví dụ này, dữ liệu cần được xử lý trong lịch xem là một bảng ghi chú hẹn trong Google Sheets. Vì vậy, thông tin cần nhập sẽ bao gồm các trường (cột) sau:
- Ngày (Cột 1)
- Tên (Cột 2)
- Email (Cột 3)
- Điện thoại (Cột 4)
- Địa điểm họp (Cột 5)
- Người tham dự (Cột 6)
- Thời gian (Cột 7)
Dưới đây là cách điền thông tin liên quan vào sheet Master:
Sau khi hoàn thành việc nhập dữ liệu vào sheet Master, hãy chuyển sang sheet CV để xem kết quả.
Đây là lịch xem hẹn trong Google Sheets:
3. Danh sách công việc trong lịch xem trên Google Sheets
Việc có một danh sách công việc là một cách tốt để ưu tiên các công việc cá nhân hoặc liên quan đến công việc của bạn.
Nếu bạn đã duy trì hoặc đang dự định duy trì một bảng tính cho danh sách công việc, việc sử dụng Google Sheets là một ý tưởng tốt.
Bạn có thể sử dụng mẫu của tôi để nhập danh sách công việc của bạn và xem chúng trong chế độ xem lịch.
Dưới đây là các bước để sử dụng mẫu lịch xem danh sách công việc trên Google Sheets:
- Trong sheet Master, nhập các ngày công việc vào cột A và công việc vào cột B.
- Chuyển sang sheet CV và chọn tháng trong ô G1 và năm trong ô H1.
- Danh sách công việc sẽ sẵn sàng để xem.
Mẫu xem lịch trên Google Sheets: Công thức chính
Chúng ta có một số công thức mảng trong sheet CV. Chúng nằm trong dải B5:B34. Một phần trong số đó dùng để điền lịch động và các công thức đó nằm trong các ô B5, B10, B15, B20, B25 và B30.
Trong các ô này, chúng ta có các công thức để truy xuất các giá trị cho lịch xem và đây là các công thức chính:
- B6: Công thức sau đây trong ô B6 truy xuất các giá trị văn bản từ cột B đến F (2 đến 6) trong sheet Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,source_txt,Master!$B$2:$F,header,Master!$B$1:$F$1,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,TEXTJOIN(CHAR(10),TRUE,UNIQUE(IFNA(FILTER(IF(LEN(source_txt),header&": "&source_txt,),DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))))))
- B7: Công thức sau đây trong ô B7 truy xuất các giá trị thời gian từ cột G (7) trong sheet Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$G$2:$G,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))))))))
- B8: Công thức sau đây trong ô B8 truy xuất các giá trị thời gian từ cột H (8) trong sheet Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$H$2:$H,month_txt,$G$1,calendar_dt,B5:H5,MAP(calendar_dt,LAMBDA(dtd,SORTN(IFNA(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1))),1,0,1,0)))))
- B9: Công thức sau đây trong ô B9 truy xuất các giá trị thời lượng hoặc số từ cột I (9) trong sheet Master.
=ARRAYFORMULA(LET(source_dt,Master!$A$2:$A,numeric,Master!$I$2:$I,month_txt,$G$1,calendar_dt,B5:H5,result,MAP(calendar_dt,LAMBDA(dtd,IFNA(SUM(FILTER(numeric,DATEVALUE(source_dt)=dtd,MONTH(source_dt)=MONTH(month_txt&1)))))),IF(result>0,result,)))
Sao chép các công thức trên từ ô B6 đến B9 và dán chúng vào các ô B11, B16, B21, B26 và B31.
Kết luận
Tôi đã đưa ra ba ví dụ để cho bạn thấy cách sử dụng mẫu xem lịch trên Google Sheets của tôi. Bạn có thể đã nhận thấy rằng không một ví dụ nào sử dụng cột thứ 9 về thời lượng/số (I) trong sheet Master. Dưới đây là cách sử dụng nó.
Giả sử bạn muốn hiển thị các khoản chi hàng ngày của bạn trong lịch xem. Hãy nhập ngày vào cột A, tiêu đề chi tiêu (mô tả) vào cột B và số tiền vào cột I. Nếu có nhiều khoản chi trong cùng một ngày, bạn có thể xử lý chúng theo hai cách:
- Nhập chúng vào hai hàng (giả sử có hai khoản chi). Điều này sẽ tạo ra hai bản ghi cho cùng một ngày. Công thức tương ứng sẽ gộp chúng (tổng hợp).
- Nhập chúng vào một hàng. Nhập các mô tả phân tách bằng dấu phẩy và thủ công cộng tổng các khoản chi và nhập tổng vào cột I.
Tương tự, bạn có thể sử dụng cột thứ 9 để nhập thời lượng, ví dụ như làm thêm giờ. Bạn có thể tự thực hiện điều này sau khi đã xem qua ba ví dụ trên.
Đó là tất cả về mẫu xem lịch trên Google Sheets. Hy vọng bạn đã thấy thú vị.
