Để đếm số công việc hoàn thành trong Google Sheets, chúng ta có thể sử dụng hàm COUNTIF kết hợp với một số hàm khác.
Có thể có người trong số các bạn nghĩ rằng bạn có thể sử dụng COUNTIF hoặc DCOUNTA một mình để làm điều tương tự. Nhưng thực tế không phải như vậy. Điều này chỉ đúng nếu một nhiệm vụ không có các nhiệm vụ phụ.
Ví dụ: giả sử một cột chứa chuỗi “Complete” hoặc hộp kiểm để hiển thị các hoạt động đã hoàn thành.
Nếu đó là cột C, bạn có thể thử công thức dưới đây.
=countif(C1:C,"Complete")Hoặc:
=DCOUNTA(C1:C,1,{"Status";"Complete"})Trong công thức DCOUNTA, tôi đã giả định rằng nhãn trường ở C1 là “Status” vì đó là một công thức cơ sở dữ liệu và yêu cầu có một hàng tiêu đề.
Lưu ý: Nếu bạn có các hộp kiểm, thay thế “Complete” trong các công thức bằng TRUE. Không bao quanh TRUE bằng dấu nháy kép vì nó là một giá trị logic.
Nếu bạn có nhiều nhóm và muốn đếm chỉ khi mỗi hàng trong mỗi nhóm hoàn thành, thì các công thức trên sẽ không hữu ích.
Trong bài hướng dẫn Google Sheets này, tôi có hai loại công thức giải pháp cho bạn. Cả hai đều sử dụng COUNTIF, nhưng các hàm hỗ trợ sẽ khác nhau.
Hãy cùng xem qua một ví dụ.
Dữ liệu mẫu và Số lượng mong muốn
Hãy xem cách đếm số công việc hoàn thành và chưa hoàn thành, ở đây là các hành động, dựa trên cột trạng thái C trong Google Sheets.
Dữ liệu mẫu trên cho thấy các yêu cầu nhận được từ nhiều khách hàng về một mặt hàng và tình trạng hiện tại với nhà cung cấp.
Một công ty nhận được yêu cầu từ bốn khách hàng – Khách hàng A, B, C và D.
Trừ khách hàng B, các đơn hàng của ba công ty khác đã được hoàn thành.
Làm thế nào để đếm cột trạng thái nếu chỉ khi tất cả các trạng thái đối với một công ty đều hiển thị “Complete”?
Theo dữ liệu trên, kết quả mong muốn như sau.
- Công việc đã hoàn thành – 3
- Công việc chưa hoàn thành – 1
Công thức để đếm Công việc hoàn thành trong Google Sheets
Đầu tiên, chúng ta phải tìm cách đếm tổng số công việc đã hoàn thành. Sau đó, sẽ dễ dàng để chúng ta tìm tổng số công việc chưa hoàn thành.
Bởi vì:
Tổng số công việc chưa hoàn thành = Tổng số công việc duy nhất - Tổng số công việc đã hoàn thànhChi tiết hơn về phần này có thể tìm thấy dưới tiêu đề “Công thức để đếm Công việc chưa hoàn thành trong Google Sheets” ở cuối.
Tùy chọn Công thức # 1
Dưới đây là công thức để đếm tổng số công việc đã hoàn thành hoàn chỉnh.
=ArrayFormula(countif(IFNA(vlookup(UNIQUE(A2:A),sort(A2:C,3,0),3,0)),"Complete"))Chèn công thức trên vào ô F2, nó sẽ trả về 3 dựa trên dữ liệu mẫu trên (hình ảnh số 1).
COUNTIF là yếu tố quan trọng, nhưng chúng ta phải chuẩn bị dữ liệu trước khi sử dụng nó. VLOOKUP làm điều đó với sự giúp đỡ của UNIQUE và SORT.
Dưới đây là giải thích cho mỗi bước trong công thức trên để đếm công việc đã hoàn thành trong Google Sheets.
Giải thích Công thức Phần # 1:
=UNIQUE(A2:A)Công thức trên sẽ trả về các khách hàng duy nhất.
Giải thích Công thức Phần # 2:
=sort(A2:C,3,0)Công thức SORT trên sắp xếp các giá trị cột thứ ba (cột trạng thái) theo thứ tự giảm dần. Vì vậy, các hàng được đánh dấu với hành động “Chưa hoàn thành” sẽ nằm trên cùng.
Giải thích Công thức Phần # 3:
vlookup(UNIQUE(A2:A),sort(A2:C,3,0),3,0)Phần công thức 3 là VLOOKUP. Phần công thức trên số 1 đóng vai trò như search_keys trong VLOOKUP và phần công thức trên số 2 đóng vai trò như phạm vi của nó.
VLOOKUP sẽ trả về các giá trị từ cột thứ ba từ phạm vi này.
Trong một phạm vi cột không được sắp xếp, công thức sẽ trả về các giá trị từ lần xuất hiện đầu tiên.
Điều đó có nghĩa là, công thức sẽ trả về các giá trị như dưới đây (cột thứ hai trong bảng):
| Phần kết quả Công thức # 1 | Kết quả Công thức # 3 |
|---|---|
| A | Complete |
| B | Complete |
Sử dụng COUNTIF trong hai cột này, chúng ta có thể đếm số công việc đã hoàn thành trong Google Sheets.
Sử dụng IFNA để loại bỏ lỗi #N/A và COUNTIF để đếm cột 2 nếu giá trị là “Complete”.
Tùy chọn Công thức # 2
So với công thức trước đó, đây là một công thức ngắn hơn.
=countif(sortn(sort({A2:A,C2:C},2,0),9^9,2,1,0),"Complete")Như tôi đã nói nhiều lần, SORTN là một trong những hàm tốt nhất trong Google Sheets. Hãy xem nó có ích như thế nào ở đây.
Hãy hiểu rõ các phần công thức.
Ở đây, phần công thức trước đó số 1 (duy nhất) không áp dụng.
Phần công thức thứ 2 (sắp xếp) nằm ở đây. Nó chỉ yêu cầu các cột A và B trong quá trình sắp xếp.
Do đó, sử dụng {A2:A,C2:C} thay vì A2:C trong quá trình sắp xếp.
Ở đây, cột trạng thái C cũng được sắp xếp theo thứ tự giảm dần. Vui lòng xem hình ảnh số 2 ở trên để biết kết quả sắp xếp. Cột H trong kết quả sắp xếp sẽ không có ở đây.
SORTN loại bỏ các hàng khách hàng trùng lặp dựa trên cột 1. Vì vậy, kết quả sẽ tương tự với bảng số 1 ở trên.
Ở đây cũng vậy, COUNTIF làm phần còn lại.
Bạn đã có hai tùy chọn công thức để đếm công việc đã hoàn thành trong Google Sheets. Còn việc đếm các hoạt động chưa hoàn thành thì sao?
Công thức để đếm Công việc chưa hoàn thành trong Google Sheets
Tôi đã đưa ra một công thức chung ngay trên lớp ở chỗ “Tùy chọn Công thức # 1”. Hãy tham khảo trước.
Sử dụng COUNTUNIQUE(A2:A), chúng ta có thể lấy tổng số lượng khách hàng hoặc công việc duy nhất. Theo ví dụ của chúng tôi, nó sẽ là 4.
Từ đó, trừ đi đầu ra của kết quả trên.
Vì vậy, công thức sử dụng Tùy chọn Công thức # 1 sẽ là:
=COUNTUNIQUE(A2:A)-ArrayFormula(countif(IFNA(vlookup(UNIQUE(A2:A),sort(A2:C,3,0,1,1),3,0)),"Complete"))Và công thức Tùy chọn Công thức # 2 sẽ là:
=COUNTUNIQUE(A2:A)-countif(sortn(sort({A2:A,C2:C},2,0),9^9,2,1,0),"Complete")Chúng ta có thể sử dụng bất kỳ công thức nào trên để đếm các công việc chưa hoàn thành cho dữ liệu mẫu được cung cấp trong Google Sheets.
Đó là tất cả! Hãy thử ngay thôi.
Đọc thêm: Đánh dấu Công việc là Hoàn thành khi tất cả các Công việc phụ đã Kết thúc trong Sheets.
