Nếu bạn đang tìm cách để trích xuất chữ cái đầu tiên của mỗi từ trong Google Sheets, dưới đây là hai công thức mảng mà bạn có thể áp dụng. Trong số đó, có một công thức rất khéo léo và dễ sử dụng.
Thường thì để trích xuất chữ cái đầu tiên của mỗi từ, chúng ta thường sử dụng các bước dưới đây trong Google Sheets (Tôi sẽ không áp dụng nó vào việc viết công thức mảng).
Hãy giả sử ô A2 chứa chuỗi từ “medium weight beam”.
Tôi muốn trích xuất các chữ cái “m”, “w”, và “b” và kết hợp chúng thành một chữ viết tắt như “mwb”.
Thường thì, chúng ta sẽ giải quyết vấn đề trên bằng cách SPLIT, LEFT và JOIN như sau và kéo nó xuống áp dụng cho chuỗi trong hàng tiếp theo.
Các bước (giải thích công thức):
- Chúng ta có thể sử dụng hàm SPLIT để chia chuỗi thành ba phần dựa trên dấu cách.
=split(A2," ")
- Sau đó, sử dụng hàm LEFT, chúng ta có thể trích xuất chữ cái đầu tiên từ mỗi từ.
=ArrayFormula(left(split(A2," "),1))
Tôi đã sử dụng ArrayFormula trong công thức trên vì chúng ta muốn trích xuất chữ cái đầu tiên từ nhiều từ (được chia) hơn một.
- Chỉ cần kết hợp kết quả.
=JOIN("",ArrayFormula(left(split(A2," "),1)))
Để tránh lỗi trong trường hợp không có giá trị trong ô A2, nên bọc công thức trong IFERROR.
Trên đây là phương pháp không sử dụng công thức mảng tốt nhất để trích xuất chữ cái đầu tiên của mỗi từ trong Google Sheets.
Nhưng công thức này cũng có một vấn đề.
Vì chúng ta đã sử dụng hàm JOIN, việc viết một công thức mảng theo phương pháp trên có thể khó khăn.
Chúng ta chỉ có thể sử dụng một phần của công thức đó mà tôi sẽ giải thích sau.
Ở đây, tôi có hai giải pháp thay thế cho vấn đề trên. Một trong số đó rất khéo léo và dễ sử dụng hơn phương pháp không sử dụng công thức mảng trên.
Hai công thức mảng để trích xuất chữ cái đầu tiên của mỗi từ trong Google Sheets
Dưới đây là hai công thức với tựa đề Array Formula 1 và Array Formula 2.
Tôi khuyến nghị sử dụng công thức mảng 1.
Nếu bạn không quan tâm đến sự phân biệt hoa thường của các chữ cái được trích xuất, hãy sử dụng nó. Đây là cách đơn giản nhất để trích xuất chữ cái đầu tiên của mỗi từ trong Google Sheets.
Công thức mảng 1 sẽ chuyển đổi tất cả các chữ cái đã trích xuất sang chữ hoa. Nếu bạn muốn, bạn có thể chuyển nó thành chữ thường.
Sử dụng công thức mảng 2 nếu bạn muốn một công thức nhạy cảm đến sự phân biệt hoa thường. Ý nghĩa là, các chữ cái đã trích xuất sẽ giống như trong chuỗi gốc. Nó không thay đổi chữ hoa thường của các chữ cái.
Công thức mảng 1
Hãy xem xét chuỗi giống như trong ô A2, đó là “medium weight beam”.
Đây là cách đơn giản nhất để viết tắt chuỗi trên trong Google Sheets.
Các bước:
- Sử dụng hàm PROPER để biến chữ cái đầu tiên của mỗi từ thành chữ hoa và các chữ cái khác thành chữ thường.
=proper(A2)
Kết quả sẽ là “Medium Weight Beam”.
- Sử dụng REGEXREPLACE, chúng ta có thể trích xuất chỉ các chữ hoa từ chuỗi trên.
=REGEXREPLACE(proper(A2),"[^A-Z]+","")
Vì không chứa hàm JOIN, chúng ta có thể dễ dàng biến nó thành một công thức mảng.
=ArrayFormula(REGEXREPLACE(proper(A2:A),"[^A-Z]+",""))
Công thức mảng 2
Để có thêm một công thức mảng để trích xuất chữ cái đầu tiên của mỗi từ trong Google Sheets, làm theo các bước dưới đây.
Ở đây, chúng ta sẽ SPLIT các chuỗi, sau đó trích xuất chữ cái đầu tiên bằng cách sử dụng LEFT. Thay vì JOIN, chúng ta sẽ sử dụng QUERY để kết hợp các chữ cái đã trích xuất.
- Hãy trước tiên FILTER phạm vi A2:A để bỏ qua các hàng trống.
=filter(A2:A,A2:A<>"")
- Chia các chuỗi đã lọc.
=ArrayFormula(split(filter(A2:A,A2:A<>"")," "))
- Hãy trích xuất chữ cái đầu tiên trong mỗi từ.
=ArrayFormula(left(split(filter(A2:A,A2:A<>"")," "),1))
- Sử dụng QUERY, chúng ta có thể kết hợp các chữ cái đã trích xuất. Tôi có một hướng dẫn chi tiết về việc sử dụng QUERY để kết hợp các chuỗi tại đây – The Flexible Array Formula to Join Columns in Google Sheets.
Làm thế nào nó hoạt động?
Chúng ta có thể sử dụng HEADER của QUERY cho điều này. Chúng ta sẽ sử dụng một số nguyên tố lớn ở tiêu đề. Vì vậy, QUERY sẽ coi tất cả các hàng trong phạm vi là tiêu đề và kết hợp chúng thành một hàng duy nhất.
4.1. Sử dụng TRANSPOSE để thay đổi hướng kết quả công thức trên.
=TRANSPOSE(ArrayFormula(left(split(filter(A2:A,A2:A<>"")," "),1)))
4.2. Sử dụng QUERY để kết hợp các chữ cái.
=query(transpose(ArrayFormula(left(split(filter(A2:A,A2:A<>"")," "),1))),,9^9)
4.3. Một lần nữa, thay đổi kết quả bằng cách chuyển vị.
=transpose(query(transpose(ArrayFormula(left(split(filter(A2:A,A2:A<>"")," "),1))),,9^9))
Trên đây là công thức mảng để trích xuất chữ cái đầu tiên từ mỗi từ trong Google Sheets.
Nhưng đợi đã. Hãy xem kết quả. Câu truy vấn để lại khoảng trắng giữa các chữ cái đã kết hợp.
Bạn có thể sử dụng REGEXREPLACE hoặc SUBSTITUTE để loại bỏ chúng.
=ArrayFormula(substitute(transpose(query(transpose(left(split(filter(A2:A,A2:A<>"")," "),1)),,9^9))," ",""))
Lưu ý: Nếu bạn có các ô trống giữa các giá trị trong A2:A, hãy sử dụng công thức dưới đây. Trong công thức này, tôi đã bỏ qua FILTER và bao gồm IFERROR sau SPLIT.
=ArrayFormula(substitute(transpose(query(transpose(left(iferror(split(A2:A," ")),1)),,9^9))," ",""))
Hi vọng bạn đã hiểu cách trích xuất chữ cái đầu tiên từ mỗi từ trong Google Sheets.
Cảm ơn bạn đã ở lại. Chúc bạn thú vị!
