Để lọc các số có chữ số duy nhất trong Google Sheets, trước tiên bạn cần biết cách kiểm tra xem một số đã cho có chứa các chữ số duy nhất hay không. Điều này cũng áp dụng cho việc tô sáng (định dạng điều kiện).
Một số có chữ số duy nhất có nghĩa là một số với các chữ số duy nhất. Ví dụ, 98765 là một số có chữ số duy nhất (đây cũng là số có 5 chữ số duy nhất lớn nhất).
Một ví dụ khác là 10234 (đây là số có 5 chữ số duy nhất nhỏ nhất).
Chúng ta không đang nói về số có chữ số duy nhất lớn nhất hoặc nhỏ nhất. Chủ đề của chúng ta là số có chữ số duy nhất.
Nó có thể là số nhỏ nhất, lớn nhất hoặc có thể chứa bất kỳ số chữ số nào nhưng các chữ số trong số đó phải là duy nhất hoặc không được lặp lại.
Trong bài viết này, chúng ta sẽ tìm hiểu cách lọc các số có chữ số duy nhất từ một danh sách số trong Google Sheets.
Cách lọc các số có chữ số duy nhất trong Google Sheets
Có 4 bước liên quan. Đó là trích xuất các chữ số, làm cho chúng duy nhất và đếm, so khớp đếm với độ dài của số đang xét và lọc.
Trích xuất các chữ số từ một số vào một cột
Như đã đề cập ở trên, để kiểm tra xem tất cả các chữ số trong số có duy nhất hay không, chúng ta cần trích xuất tất cả các chữ số trước tiên. Chúng ta có thể sử dụng công thức sau đây để làm điều đó (trích xuất các chữ số).
Nếu số đó ở trong ô B2, chúng ta có thể sử dụng công thức kết hợp sau đây (luôn đọc công thức kết hợp từ giữa):
=TRANSPOSE(split(REGEXREPLACE(B2&"",".{1}", "$0,"),","))Có thêm hai công thức nữa mà chúng ta có thể sử dụng cho mục đích tương tự. Bạn có thể tìm các công thức đó ở đây – Split a Number to Digits in Google Sheets. Nhưng tôi thoải mái với kết hợp trên.
Giải thích công thức
Chìa khóa là công thức REGEXREPLACE, nó chèn (đặt) dấu phẩy sau mỗi chữ số.
=REGEXREPLACE(B2&"",".{1}", "$0,")Kết quả: 1,2,0,5,6,7,8,
Cú pháp: REGEXREPLACE(text, regular_expression, replacement)
Phần .{1} của công thức REGEXREPLACE (regular_expression) khớp với bất kỳ ký tự nào (ngoại trừ dấu kết thúc dòng) một lần.
Đúng! nó khớp với ‘ký tự’. Đó là lý do tôi đã định dạng số trong ô B2 thành văn bản bằng cách nối một ký tự null vào đó, tức là B2&””.
Phần $0, của công thức REGEXREPLACE (replacement), chèn một dấu phẩy sau mỗi chữ số.
Lưu ý: Nếu bạn sử dụng (.{1}) làm regular_expression, thì replacement phải là “$1. Nó tương đương với công thức trên.
Công thức SPLIT chia các chữ số làm dấu phân tách để chia là “,”.
Các chữ số bị chia sẽ được đặt trong một hàng. Chức năng Transpose giúp thay đổi hướng của chúng thành một cột để chúng ta có thể sử dụng điều này trong Unique.
Dùng Unique và Đếm các Chữ số đã Trích xuất
Hãy làm cho các chữ số trở nên duy nhất bằng cách bọc công thức trên bằng Unique. Công thức dưới đây (unique_digits_formula) loại bỏ các chữ số lặp lại từ các chữ số đã trích xuất.
=unique(TRANSPOSE(split(REGEXREPLACE(B2&"",".{1}", "$0,"),",")))
Kiểm tra xem số đã cho có phải là số có chữ số duy nhất trong Google Sheets hay không
Bây giờ để kiểm tra xem số đã cho có phải là số có chữ số duy nhất trong Google Sheets, chỉ cần kiểm tra xem số lượng các chữ số trong đầu ra của công thức trên có khớp với độ dài của số trong ô B2 hay không.
Chúng ta có thể lấy độ dài của số trong ô B2 bằng cách sử dụng LEN như sau.
=len(B2)Để lấy số lượng các chữ số duy nhất, bọc công thức trước đó của chúng ta bằng COUNTA (bạn cũng có thể sử dụng COUNT). Điều đó có nghĩa là theo mẫu chung;
=counta(unique_digits_formula)=len(B2)Đây là công thức để kiểm tra xem số đã cho có phải là số có chữ số duy nhất trong Google Sheets.
=counta(unique(TRANSPOSE(split(REGEXREPLACE(B2&"",".{1}", "$0,"),","))))=len(B2)Công thức trên sẽ trả về GIẢ nếu số không phải là số có chữ số duy nhất, ngược lại là ĐÚNG.
Lọc (Có Sử Dụng Cột Trợ giúp)
Khi có một danh sách số trong một cột trong Google Sheets và bạn muốn chỉ lọc các số có chữ số duy nhất, hãy sử dụng phương pháp sau đây.
Danh sách theo ví dụ của tôi nằm trong ô B2:B8. Công thức trên của tôi nằm trong ô D2. Kéo công thức D2 đến D8. Sau đó, sử dụng công thức Lọc dưới đây trong ô F2.
=filter(B2:B8,D2:D8=TRUE)
Công thức Lọc lọc B2:B8 nếu cột D2:D8 là ĐÚNG.
Lọc (Không Sử Dụng Cột Trợ giúp) Các số duy nhất theo Màu của Ô
Đây là một mẹo bổ sung. Thay vì lọc, nếu bạn muốn tô sáng các số có chữ số duy nhất trên một bảng tính, chúng ta có thể sử dụng quy tắc công thức sau đây.
- Chọn phạm vi, ở đây là B2:B8.
- Nhấp vào Định dạng > Định dạng điều kiện > Luật định dạng > Luật tùy chỉnh.
Trong trường trống được cung cấp, sao chép dán công thức sau đây.
=counta(unique(TRANSPOSE(split(REGEXREPLACE(B2&"",".{1}", "$0,"),","))))=len(B2)Đây là công thức mà bạn có thể tìm thấy ngay trên phần đầu “Lọc (Cột Trợ giúp)”.
Bây giờ bạn có thể lọc màu sắc nổi bật bằng tính năng Lọc theo Màu (Dữ liệu > Tạo bộ lọc > Lọc theo màu).
Làm thế nào để tô sáng Chỉ các số duy nhất N Chữ số trong Google Sheets
Tôi muốn chỉ tô sáng các số có 5 chữ số và các chữ số là duy nhất. Vậy làm thế nào?
Nếu đây là câu hỏi của bạn, câu trả lời rất đơn giản. Chỉ cần sử dụng toán tử AND với công thức trước đó để kiểm tra xem số có 5 chữ số khác duy nhất hay không.
=and(counta(unique(TRANSPOSE(split(REGEXREPLACE(B2&"",".{1}", "$0,"),","))))=len(B2),len(B2)=5)Trong công thức này, len(B2)=5 kiểm soát số n.
Đó là tất cả. Chúc vui vẻ!
