Khi lấy dữ liệu lịch sử, nếu bạn sử dụng các tham số start_date và end_date, hàm GoogleFinance sẽ trả về hai cột dữ liệu. Điều này đưa ra một câu hỏi! Đó là làm thế nào để tìm giá trị lớn nhất và nhỏ nhất trong dữ liệu lịch sử của GoogleFinance?
Nếu đó là dữ liệu một cột duy nhất, không có nghi ngờ gì, bạn có thể sử dụng các hàm MIN hoặc MAX. Ngay cả khi đó là một mảng hai cột, nếu bất kỳ cột nào chứa giá trị văn bản, các hàm trên sẽ hoạt động.
Nhưng trong Google Sheets, hàm GoogleFinance trả về dữ liệu hai cột. Trong đó, cột đầu tiên chứa ngày giờ và cột thứ hai chứa các giá trị lịch sử.
Đó là lý do tại sao câu hỏi về cách tìm giá trị lớn nhất và nhỏ nhất trong dữ liệu lịch sử của GoogleFinance trở nên quan trọng.
Để tìm giá trị lớn nhất và nhỏ nhất trong GoogleFinance, tôi có các tùy chọn công thức khác nhau để trình bày trước mắt bạn. Bạn có thể chọn cách đơn giản nhất từ các đề xuất công thức của tôi.
Các Lựa Chọn Để Tìm Giá Trị Lớn Nhất Và Nhỏ Nhất Trong Dữ Liệu Lịch Sử Của GoogleFinance
Bạn có thể sử dụng bất kỳ trong số các hàm dưới đây để áp dụng Min và Max trong dữ liệu lịch sử nhiều hàng trong Google Sheets.
- Query.
- DMAX/DMIN Các Hàm Cơ Sở Dữ Liệu.
- Hàm MAX/MIN với INDEX (công thức kết hợp).
Trước hết, cho tôi cho bạn xem cấu trúc của một đầu ra dữ liệu lịch sử Google Finance.
=GOOGLEFINANCE("NSE:HDFC", "VOLUME", TODAY()-15, TODAY())
Công thức GoogleFinance này lấy khối lượng giao dịch trong 15 ngày qua cho mã chứng khoán “HDFC”. Đó là dữ liệu lịch sử nên nó sẽ trả về đầu ra mở rộng như dưới đây.
Dữ liệu lịch sử Hai Cột:
Trong đó, tôi đã sử dụng thuộc tính “volume”. Các thuộc tính được hỗ trợ khác trong dữ liệu lịch sử bao gồm “open”, “close”, “high”, “low” và “all”.
Trong đó, ngoại trừ thuộc tính “all”, tất cả các thuộc tính sẽ trả về dữ liệu hai cột như trên.
Nếu bạn sử dụng thuộc tính “all”, nó sẽ trả về một đầu ra nhiều cột như dưới đây.
Dữ liệu lịch sử Nhiều Cột:
Không cần phải nói, công thức để truy xuất giá trị lớn nhất và nhỏ nhất trong dữ liệu lịch sử GoogleFinance sẽ thay đổi trong hai cột cũng như trong đầu ra nhiều cột.
Tìm Các Giá Trị Lớn Nhất Trong Dữ Liệu Lịch Sử Hai Cột Của GoogleFinance
Hãy để tôi bắt đầu với công thức Query. Tôi thích Query vì nó dễ đọc.
Công Thức Query Để Tìm Giá Trị Lớn Nhất Trong Dữ Liệu Lịch Sử Của GoogleFinance
Cú pháp:
QUERY(data, query, [headers])
Sử dụng công thức dữ liệu lịch sử GoogleFinance của bạn như là “data” trong Query. Chúng ta có thể sử dụng hàm tổng hợp Max trong “query”.
Công thức:
=QUERY(GOOGLEFINANCE("NSE:HDFC", "VOLUME", TODAY()-15, TODAY()), "Select Max(Col2) label Max(Col2)''", 1)
Bạn Có Thể Thích: Cách Tính Tổng, Trung Bình, Đếm, Max Và Min Trong Truy Vấn Google Sheets.
Hàm Cơ Sở Dữ Liệu DMAX Trong Dữ Liệu Lịch Sử Của GoogleFinance (Dữ Liệu Nhiều Hàng)
Dữ liệu lịch sử GoogleFinance được cấu trúc tốt như một bảng cơ sở dữ liệu. Nó có nhãn trường trong hàng đầu tiên. Điều đó làm cho dữ liệu đủ điều kiện để sử dụng trong hàm DMAX.
Nhãn trường cho cột đầu tiên là “Date”. Nhưng nhãn trường cho cột thứ hai phụ thuộc vào thuộc tính đang sử dụng.
Trong ví dụ của tôi, đó là “Volume” trong dữ liệu hai cột. Bạn có thể kiểm tra ảnh chụp màn hình liên quan ở trên.
Những gì tôi đang cố gắng nói là, trong dữ liệu được cấu trúc, bạn có thể sử dụng hàm cơ sở dữ liệu DMAX để trả về giá trị lớn nhất.
Cú pháp:
DMAX(database, field, criteria)
Công thức:
=DMAX(GOOGLEFINANCE("NSE:HDFC", "VOLUME", TODAY()-15, TODAY()), 2, {"Date"; ">"&text("30/12/1899", "dd/mm/yyyy")})
Tôi đã giải thích việc sử dụng này trong hướng dẫn của tôi liên quan đến hàm DMAX.
Kết Hợp MAX và INDEX Để Tìm Cột Trong Dữ Liệu Nhiều Hàng
Công thức:
=max(index(GOOGLEFINANCE("NSE:HDFC", "VOLUME", TODAY()-15, TODAY()), 0, 2))
Ở đây, công thức INDEX (xem bên dưới) lùi đi 2 cột. Vì vậy, bạn chỉ còn lại cột thứ hai.
=index(GOOGLEFINANCE("NSE:HDFC","VOLUME",TODAY()-15,TODAY()),0,2)
Điều đó có nghĩa là bạn chỉ cần bọc công thức Index này với chức năng Max thông thường để tìm giá trị lớn nhất.
Tìm Giá Trị Nhỏ Nhất Trong Dữ Liệu Lịch Sử Hai Cột Của GoogleFinance
Ở đây, tôi sẽ trực tiếp đưa cho bạn ba công thức khác nhau. Các công thức này có chỉ một điểm khác biệt chung so với các công thức trên. Đó là gì?
Để tìm giá trị nhỏ nhất từ Dữ Liệu Lịch Sử Của Google Finance, hãy thay đổi hàm MAX thành MIN như sau.
Query:
=QUERY(GOOGLEFINANCE("NSE:HDFC","VOLUME",TODAY()-15,TODAY()),"Select Min(Col2) label Min(Col2)''",1)
DMIN:
=DMIN(GOOGLEFINANCE("NSE:HDFC","VOLUME",TODAY()-15,TODAY()),2,{"Date";">"&text("30/12/1899","dd/mm/yyyy")})
MIN/Index:
=MIN(index(GOOGLEFINANCE("NSE:HDFC","VOLUME",TODAY()-15,TODAY()),0,2))
Bạn Cần Đọc: Hướng Dẫn Các Hàm Google Sheets.
Tìm Giá Trị Lớn Nhất Và Nhỏ Nhất Trong Dữ Liệu Lịch Sử Nhiều Cột Trong Google Sheets
Trong tất cả các công thức trên, tôi trích xuất cột 2 và sau đó thực hiện Max hoặc Min. Trong dữ liệu nhiều cột, điều đó có thể hoặc không thể là cột 2 để trích xuất.
Hãy xem ảnh chụp màn hình ví dụ dưới đây. Trong đó, tôi đã đánh dấu cột 5. Làm thế nào để tìm giá trị lớn nhất/nhỏ nhất trong cột đó?
Thay đổi trong Công Thức:
- Trong Query, bạn chỉ cần thay đổi số cột thành 5 trong chức năng Max tổng hợp và trong nhãn cũng như.
- Đối với DMAX hoặc DMIN, thay đổi số trường thành 5.
- Trong Min/Max Index kết hợp, thay đổi số lùi cột thành 5. Làm thế nào?
Query:
=QUERY(GOOGLEFINANCE("NSE:HDFC","ALL",TODAY()-15,TODAY()),"Select Max(Col5) label Max(Col5)''",1)
Thay đổi: “Col2” thành “Col5”.
DMAX:
=DMAX(GOOGLEFINANCE("NSE:HDFC","ALL",TODAY()-15,TODAY()),5,{"Date";">"&text("30/12/1899","dd/mm/yyyy")})
Thay đổi: Số trường 2 thành 5.
MIN/Index:
=MAX(index(GOOGLEFINANCE("NSE:HDFC","ALL",TODAY()-15,TODAY()),0,5))
Thay đổi: Số cột lùi 2 thành 5.
Cách này bạn có thể tìm giá trị nhỏ nhất từ dữ liệu lịch sử GoogleFinance nhiều cột. Đối với điều đó, chỉ cần thay đổi Max thành Min.
Tài Nguyên Bổ Sung:
- Cách Tìm Giá Trị Lớn Nhất Trong Mỗi Hàng Trong Google Sheets [Công Thức Mảng].
- Vlookup Chỉ Trả Về Các Giá Trị Từ Các Hàng Cao Nhất Trong Google Sheets.
- Cách Loại Trừ 0 Từ Kết Quả Hàm MIN Trong Google Sheets.
- Tổng Các Giá Trị Lớn/Max n Dựa Trên Tiêu Chí Trong Google Sheets.
- Tìm N Giá Trị Lớn Nhất Trong Một Hàng Và Trả Về Tiêu Đề Trong Google Sheets.
