Bạn có thể sử dụng công thức của tôi để dễ dàng tạo danh sách mật khẩu trong Google Sheets. Để tạo ra các mật khẩu, tôi sử dụng tên người dùng và ngày sinh của họ. Mật khẩu sẽ mạnh mẽ vì nó sẽ là sự kết hợp của các ký tự chữ số và ký tự đặc biệt.
Bạn có thể sử dụng công thức của tôi để tạo mật khẩu mạnh trong Sheets để dùng cho học sinh của bạn hoặc nhân viên trong tổ chức của bạn để truy cập vào các tài khoản liên quan đến văn phòng của họ.
Tuy nhiên, tôi không khuyến nghị bạn sử dụng công thức của tôi để tạo mật khẩu cho các tài khoản trực tuyến quan trọng như ngân hàng, blog/website, tên miền, hosting, bảo hiểm, v.v. Nhưng điều đó không có nghĩa là mật khẩu được tạo bằng công thức Google Sheets là yếu.
Bước để Tạo Danh Sách Mật Khẩu Mạnh trong Google Sheets
Như tôi đã đề cập ở trên, chúng ta sẽ tạo mật khẩu trong Google Sheets bằng cách sử dụng tên người dùng và ngày sinh của họ.
Trong “Sheet1”, nhập tên người dùng, tức là tên của học sinh hoặc nhân viên, vào cột A và ngày sinh vào cột B. Không bao gồm khoảng trắng trong tên. Ví dụ, “Prashanth KV” phải nhập là “PrashanthKV”.
Trong “Sheet2”, ở ô A1, nhập công thức sau để tạo ra các ký tự chữ cái từ a đến z.
Formula #1:
=ArrayFormula({"Formula #1";lower(regexreplace(address(1,row(A1:A26)),"[^A-Z]",""))})Bạn có thể tìm hiểu thêm về cách hoạt động của công thức này tại đây – Cách Tự Điền Các Ký Tự Chữ Cái trong Google Sheets.
Ở một cột khác, cột B, trên cùng Sheet, bạn hãy nhập các ký tự đặc biệt mà bạn muốn bao gồm vào mật khẩu. Tối đa là 26 ký tự (26 hàng).
Bây giờ, điều chúng ta muốn là công thức để tạo mật khẩu trong ô C1 trong “Sheet1”.
Tôi sẽ không cung cấp công thức mà tạo ra một danh sách mật khẩu trong Google Sheets. Thay vào đó, bạn sẽ nhận được một công thức trong ô C2 trong “Sheet1” mà bạn cần kéo xuống. Điều này đảm bảo rằng mật khẩu được cung cấp đủ mạnh để sử dụng.
Hãy để tôi từng bước đi qua từng bước trong công thức viết. Bạn sau đó có thể tinh chỉnh công thức theo ý muốn. Dưới đây là các bước.
Ngẫu nhiên viết hoa các chữ cái trong một tên trong Google Sheets
Để làm cho mật khẩu mạnh, khuyến nghị pha trộn các chữ cái viết thường và viết hoa trong mật khẩu.
Như tôi đã nói, chúng ta sẽ tạo một danh sách mật khẩu mạnh trong Google Sheets. Vì vậy, chúng ta không thể bỏ qua bước này. Hãy xem cách tôi viết hoa một số chữ cái trong tên.
Để viết hoa các chữ cái ở giữa hoặc sau chữ cái đầu tiên trong một tên, chúng ta phải tách các ký tự trong tên.
Công thức trong Sheets để tách từng ký tự trong tên như sau:
Formula #2:
=ArrayFormula(mid(A2,row(A1:indirect("A"&len(A2))),1))Để tìm hiểu thêm về công thức này, vui lòng kiểm tra hướng dẫn này – Cách Tách Một Số Ra Thành Các Ký Tự Trong Google Sheets.
Tôi sử dụng công thức REGEX sau để tách các chữ cái trong tên thành các cột riêng biệt.
Formula #3:
=split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),",")Công thức REGEXREPLACE trong công thức trên đặt dấu phẩy giữa mỗi chữ cái trong tên. Công thức SPLIT được sử dụng để tách các chữ cái thành các cột mới dựa trên dấu phẩy. Hàm LOWER chuyển tất cả các chữ cái thành chữ thường.
Để viết hoa một số chữ cái ngẫu nhiên, chúng ta có thể dựa vào hàm CODE.
Hãy sử dụng hàm CODE để trả về giá trị bản đồ Unicode của mỗi ký tự trong tên. Để làm điều đó, hãy nhập công thức trên vào giữa CODE và ấn Ctrl + Shift + Enter hoặc bọc công thức toàn bộ trong ArrayFormula.
Formula #4:
=ArrayFormula(code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),",")))Sau đó, chúng ta sẽ kiểm tra xem giá trị Unicode trả về là chẵn hay lẻ. Nếu là số chẵn, chúng ta sẽ chuyển nó thành viết hoa. Sử dụng hàm ISEVEN với IF như sau:
Công thức tổng quát:
Generic Formula:
=ArrayFormula(if(iseven(Formula #4),Formula #4-32,Formula #4))Bạn có thể hiểu công thức tổng quát này trừ việc trừ đi 32, đúng không?
Giá trị Unicode của các chữ cái viết thường (a-z) từ 97 đến 122. Vậy chữ cái viết hoa (A-Z) thì sao? Nó từ 65 đến 90.
Điều đó nghĩa là bạn có thể chuyển đổi một ký tự viết thường thành ký tự viết hoa bằng cách trừ 32 từ giá trị Unicode. Dưới đây là công thức tương đương với công thức tổng quát trên.
Formula #5:
=ArrayFormula(if(ISEVEN(code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))),code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))-32,code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))))Công thức trên trả về một số giá trị Unicode đã chỉnh sửa. Bọc nó bằng hàm CHAR để chuyển đổi giá trị Unicode thành ký tự.
Formula #6:
=ArrayFormula(char(if(ISEVEN(code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))),code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))-32,code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),",")))))
Công thức trên chuyển đổi “William” trong ô A2 thành “wiLLiam”. Hay phết, đúng không?
Hãy để công thức trên ở ô C1. Với VLOOKUP, chúng ta có thể lấy ký tự đặc biệt từ danh sách trong “Sheet2”. Làm thế nào?
Để làm điều đó, tôi sẽ sử dụng ký tự thứ hai trong tên làm khóa tìm kiếm và sử dụng dữ liệu trong Sheet2!2A2:B27 là phạm vi. Để trích xuất ký tự thứ hai, chúng ta có thể sử dụng hàm MID.
Formula #7:
=vlookup(mid(A2,2,1),Sheet2!$A$2:$B$27,2,0)Tôi đang trích xuất một ký tự đặc biệt nữa. Lần này, tôi sử dụng chữ cái cuối cùng trong tên làm khóa tìm kiếm. Thay vì MID, chúng ta có thể sử dụng hàm RIGHT lần này. Nhập công thức sau vào ô E2.
Formula #8:
=vlookup(right(A2,1),Sheet2!$A$2:$B$27,2,0)Công thức để Tạo Danh Sách Mật Khẩu Trong Google Sheets
Đến lúc kết hợp công thức 6, 7 và 8 theo thứ tự dưới đây.
=FORMULA #7 & FORMULA #6 & FORMULA #8Với sự kết hợp trên, chúng ta có thể thêm ngày sinh nằm trong cột B vào mật khẩu. Nhưng thay vì thêm ngày, chúng ta sẽ trích xuất một số chữ số từ ngày.
Mình nghĩ rằng chữ cái cuối cùng của tháng, ba chữ số cuối cùng của năm và ngày có thể làm mật khẩu mạnh hơn nữa.
=FORMULA #7 & FORMULA #6 & FORMULA #8 & right(text(B2,"mmm"),1)&mid(text(B2,"yyyy"),2,3)&day(B2)Công thức cuối cùng để tạo mật khẩu mạnh trong Google Sheets:
=ArrayFormula(vlookup(mid(A2,2,1),Sheet2!$A$2:$B$27,2,0)&JOIN("",char(if(ISEVEN(code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))),code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),","))-32,code(split(REGEXREPLACE(LOWER(A2),"(.{1})", "$1,"),",")))))&vlookup(right(A2,1),Sheet2!$A$2:$B$27,2,0)&right(text(B2,"mmm"),1)&mid(text(B2,"yyyy"),2,3)&day(B2))Nhập công thức này vào ô C2 và sao chép xuống.
Đó là tất cả về cách tạo danh sách mật khẩu mạnh trong Google Sheets. Nếu bạn đang tìm kiếm một mẫu từ khóa tạo mật khẩu trong Sheets, hãy sử dụng bản sao của Sheets dưới đây.
Sample050819
