Hàm IFS trong Google Sheets giúp đơn giản hóa việc đánh giá nhiều điều kiện. Nó trả về kết quả liên quan đến điều kiện đầu tiên đúng, loại bỏ việc sử dụng lồng IF lồng nhau.
Hàm logic là một công cụ cơ bản cho người dùng bảng tính. Người mới thường bắt đầu với các hàm tổng hợp như SUM và AVERAGE, nhưng nhanh chóng tiến bộ để làm chủ các hàm logic cơ bản như IF, IFS, AND, NOT và OR.
Những hàm này cho phép thực hiện nhiều nhiệm vụ khác nhau như kiểm tra các điều kiện, đưa ra quyết định và xử lý lỗi. Hàm IFS xuất sắc trong những lĩnh vực này.
Khác với hàm IF, cần lồng (đặt một IF trong IF khác) cho nhiều điều kiện, IFS có thể xử lý nhiều điều kiện cùng một lúc. Điều này giúp đơn giản và tổ chức hơn khi xử lý nhiều điều kiện mà không làm phức tạp công thức của bạn.
Cú pháp và đối số của Hàm IFS
Cú pháp:
IFS(condition1, value1, [condition2, value2, ...])
Trong cú pháp này, condition1 và value1 là các đối số bắt buộc; các đối số khác là tùy chọn.
Đối số:
- condition1: Một điều kiện đánh giá là TRUE hoặc FALSE.
- value1: Giá trị trả về nếu condition1 là TRUE.
- condition2, value2, …: Các điều kiện và giá trị bổ sung nếu các điều kiện trước đó được đánh giá là sai.
Happens what when condition1 evaluates to FALSE and condition2 is not specified?
Công thức sẽ trả về #N/A.
Khai thác sức mạnh của IFS: Ví dụ trong Google Sheets (cùng hình ảnh)
Đây là một số ví dụ để giúp bạn làm quen với việc sử dụng hàm logic IFS trong Google Sheets.
Ví dụ cơ bản
Hãy xem xét một tình huống trong đó ô A1 chứa tên của một học sinh và ô B1 chứa tổng số điểm của anh ta trên tổng số 1000.
Nếu điểm số của anh ta lớn hơn hoặc bằng 500, bạn muốn nhận kết quả “Được chọn” trong ô C1.
Đây là cách sử dụng hàm IFS:
=IFS(B1>=500, "Được chọn")
Nếu điểm số của anh ta nhỏ hơn 500, công thức có thể trả về #N/A, chỉ ra không tìm thấy kết quả phù hợp. Để loại bỏ lỗi #N/A, bạn có thể chỉ định condition2 đánh giá là TRUE, như 1=1, và chỉ định value2 hoặc để value2 trống:
=IFS(B1>=500, "Được chọn", 1=1,)
Công thức trên sẽ trả về “Được chọn” nếu giá trị trong ô B1 là >= 500; nếu không, nó trả về trống thay vì #N/A. Để trả về “Bị từ chối” thay vì trống, chỉ định value2 như sau:
=IFS(B1>=500, "Được chọn", 1=1, "Bị từ chối")
Các điểm cần lưu ý:
- Nếu value1, value2, … là văn bản hoặc ký tự đặc biệt, hãy đặt chúng trong dấu ngoặc kép.
- Nếu value1, value2, … là số, không sử dụng dấu ngoặc kép.
- Nếu value1, value2, … đại diện cho ngày, giờ hoặc dấu thời gian, chỉ định chúng bằng các hàm ngày thích hợp hoặc kết hợp các hàm:
- Ngày: DATE(năm, tháng, ngày)
- Giờ: TIME(giờ, phút, giây)
- Dấu thời gian: DATE(năm, tháng, ngày) + TIME(giờ, phút, giây)
Sử dụng DateTime làm Output (value1):
Dưới đây là một ví dụ sử dụng hàm IFS với DateTime làm Output (value1):
=IF(B1<600, DATE(2023, 12, 12)+TIME(10, 30, 0))
Điều này sẽ trả về “12/12/2023 10:30:00” nếu giá trị trong B1 nhỏ hơn 600. Để trả về bất kỳ văn bản nào kèm theo ngày, bạn có thể sử dụng hàm JOIN:
=IF(B1<600, JOIN("", "Ngày hẹn là ", DATE(2023, 12, 12)+TIME(10, 30, 0)))
Nó sẽ trả về “Ngày hẹn là 12/12/2023 10:30:00”.
Bạn cũng có thể sử dụng Ngày, Giờ hoặc DateTime trong phần điều kiện của hàm IFS:
=IFS(A1>DATE(2030, 12, 25), "Sự kiện sắp tới")
Hoặc sử dụng các hàm như TODAY(), NOW() cả trong phần điều kiện và phần giá trị:
=IFS(A1>TODAY(), "Ngày trong tương lai", 1=1, TODAY())
Hy vọng những ví dụ cơ bản này giúp bạn hiểu về việc sử dụng hàm logic IFS trong Google Sheets.
Nhiều điều kiện trong Hàm IFS
Một cách hiệu quả để tìm hiểu về việc sử dụng nhiều điều kiện trong hàm IFS là thông qua một ví dụ về quá khứ, hiện tại và tương lai. Ví dụ này không chỉ giúp hiểu về nhiều điều kiện mà còn giới thiệu cách sử dụng công thức IFS lồng nhau.
Công thức:
=IFS(B2<TODAY(), "Quá khứ", B2=TODAY(), "Hiện tại", B2>TODAY(), "Tương lai")
Giải thích:
- B2<TODAY(): Điều kiện này kiểm tra xem ngày trong ô B2 có trước ngày hôm nay hay không. Nếu đúng, công thức trả về “Quá khứ”.
- B2=TODAY(): Điều kiện này kiểm tra xem ngày trong ô B2 có giống với ngày hôm nay hay không. Nếu đúng, công thức trả về “Hiện tại”.
- B2>TODAY(): Điều kiện này kiểm tra xem ngày trong ô B2 có sau ngày hôm nay hay không. Nếu đúng, công thức trả về “Tương lai”.
Lợi ích của kiểm tra logic này khi học hàm IFS là nó tránh trả về #N/A trừ khi ô B2 chứa một lỗi. Nó mở ra khả năng khám phá hàm IFS. Ngay cả khi ô B2 trống hoặc chứa bất kỳ giá trị nào khác ngoài một ngày, công thức vẫn trả về một trong ba giá trị “Quá khứ”, “Hiện tại” hoặc “Tương lai”.
Để giải quyết các tình huống khi ô B2 trống hoặc chứa một giá trị không phải là ngày, chúng ta có thể sử dụng một công thức IFS lồng nhau. Điều này sẽ được thảo luận trong phần tiếp theo.
IFS lồng nhau trong Google Sheets
Để xác định xem giá trị trong một ô có phải là một ngày trong Google Sheets, một phương pháp hiệu quả là sử dụng hàm DATEVALUE.
Lưu ý phụ, đối với người dùng Excel, phương pháp này chỉ áp dụng cho Google Sheets và không áp dụng cho Excel.
Dưới đây là cách nó hoạt động:
Biểu thức DATEVALUE(B2) trả về một số chuỗi biểu diễn ngày trong ô B2 hoặc một lỗi. Bọc nó với IFERROR sẽ trả về một kiểu trống hoặc một số.
Vì vậy, bạn có thể sử dụng IFERROR(DATEVALUE(B2)) làm condition1 (điều kiện đầu tiên) trong IFS và một công thức IFS khác làm value1.
=IFS( IFERROR(DATEVALUE(B2)), IFS(B2<TODAY(), "Quá khứ", B2=TODAY(), "Hiện tại", B2>TODAY(), "Tương lai"), 1=1, "Giá trị không phải là ngày hợp lệ" )
Phân tích công thức IFS lồng nhau:
- condition1: IFERROR(DATEVALUE(B2))
- value1: IFS(B2<TODAY(), “Quá khứ”, B2=TODAY(), “Hiện tại”, B2>TODAY(), “Tương lai”)
- condition2: 1=1
- value2: “Giá trị không phải là ngày hợp lệ”
Sử dụng Logic phức tạp trong Hàm IFS trong Google Sheets
Hàm IFS cho phép sử dụng logic phức tạp sử dụng các hàm như AND, OR và NOT. Dưới đây là một số ví dụ:
Giả sử có điểm số trong A1:C1, công thức IFS sau đây, kết hợp với hàm AND, kiểm tra xem tất cả các điều kiện có đúng không:
=IFS(AND(A1>60, B1>60, C1>60), "Tốt")
Công thức này đánh giá một tập hợp các điều kiện và trả về “Tốt” chỉ khi tất cả ba điều kiện (A1>60, B1>60, C1>60) đều đúng.
Tương tự, công thức IFS sau đây, kết hợp với hàm OR, kiểm tra xem ít nhất một trong các điều kiện có đúng không:
=IFS(OR(A1>60, B1>60, C1>60), "Tốt")
Công thức này trả về “Tốt” nếu bất kỳ điều kiện nào (A1>60, B1>60, C1>60) đúng.
Công thức IFS tiếp theo kết hợp các hàm logic AND và OR:
=IFS(OR(AND(A1>60, B1>60), AND(A1>60, C1>60), AND(B1>60, C1>60)), "Tốt")
Trong công thức này, nó sử dụng hàm OR để kiểm tra xem bất kỳ điều kiện nào (AND(A1>60, B1>60), AND(A1>60, C1>60), AND(B1>60, C1>60)) đúng hay không. Tóm lại, nếu hai điểm số bất kỳ lớn hơn 60, nó trả về “Tốt”.
Tương tự: Sử dụng kết hợp các hàm logic IF, AND và OR trong Google Sheets.
Trong tất cả các công thức này, kết quả sai sẽ là #N/A. Bạn có thể xử lý điều này bằng cách thêm một điều kiện mặc định bằng IFS hoặc bọc toàn bộ công thức trong hàm IFERROR.
Ví dụ:
=IFS(AND(A1>60, B1>60, C1>60), "Tốt", 1=1, "Kém")
=IFERROR(IF(AND(A1>60, B1>60, C1>60), "Tốt"), "Kém")
Liên quan: Cách sử dụng đúng các hàm AND và OR với IFS trong Google Sheets.
Thay thế IFS bằng các câu lệnh IF lồng nhau trong Google Sheets
Chúng ta có thể thay thế hàm IFS bằng các hàm IF lồng nhau trong Google Sheets. Đồng thời, nó có lợi thế hơn IFS trong một số trường hợp.
Trong một số tình huống, hàm IFS không thể trả về một mảng kết quả, yêu cầu việc sử dụng IF hoặc VLOOKUP, như đã được giải thích trong hướng dẫn của tôi: Cách sử dụng hàm IFS để trả về một mảng kết quả trong Google Sheets.
Ở đây, chúng ta sẽ tìm hiểu cách sử dụng câu lệnh IF lồng thay vì công thức IFS.
Trong ví dụ sau, chúng ta có một drop-down trong ô B1 chứa các mục “Trà”, “Cà phê” và “Sữa chua.”
Công thức IFS:
=IFS(B1="Trà", 1.5, B1="Cà phê", 2, B1="Sữa chua", 5 )
Công thức IF lồng:
=IF(B1="Trà", 1.5, IF(B1="Cà phê", 2, IF(B1="Sữa chua", 5 )))
Các công thức trên sẽ trả về 1.5, 2 và 5 nếu giá trị được chọn trong ô B1 là “Trà”, “Cà phê” hoặc “Sữa chua,” tương ứng.
Kết luận
Trong hướng dẫn này, tôi đã trình bày mọi thứ mà một người cần để hiểu rõ hàm logic IFS trong Google Sheets.
Bạn có thể sử dụng cả IF và IFS cho các kiểm tra logic trong Google Sheets. Trong số hai, IFS thân thiện hơn đối với người đọc vì IF lồng có thể khó đọc, phụ thuộc vào số lượng điều kiện.
Ngoài hai hàm này, bạn cũng có thể xem xét hàm SWITCH nếu điều kiện không liên quan đến toán tử so sánh.
