Hàm Sequence trong Google Sheets thuộc danh mục Hàm Toán (Chèn > Hàm > Toán).
Cách đơn giản nhất để tạo một mảng số tuần tự trong Google Sheets là sử dụng hàm Sequence, không phải sử dụng hàm Row như dưới đây.
Ví dụ, bạn có thể thay thế công thức =ArrayFormula(row(A1:A10)) bằng công thức đơn giản =SEQUENCE(10).
Bằng cách sử dụng hàm Sequence trong Google Sheets, bạn có thể tạo ra một mảng số tuần tự cột đơn hoặc nhiều cột. Hơn nữa, bạn cũng có thể cung cấp một giá trị bước để kiểm soát các số được tạo ra.
Ví dụ, nếu bạn cung cấp giá trị bước là 5 và giá trị bắt đầu là 0, thì các số sẽ được đánh số như sau: 0, 5, 10, 15, v.v.
Ngoài ra, hàm Sequence trong Sheets còn được sử dụng để tạo số tuần tự theo chiều dọc (một cột) hoặc theo chiều ngang (một hàng).
Thường chúng ta phụ thuộc vào hàm Row (một cột) hoặc hàm Column (một hàng) kết hợp với ArrayFormula để đạt được các kết quả như vậy. Tuy nhiên, khi bạn hiểu về hàm Sequence, bạn có thể bỏ qua việc sử dụng các công thức kết hợp này.
Hãy bắt đầu với cú pháp và các đối số của hàm Sequence trong Google Sheets.
Cú pháp:
SEQUENCE(rows, columns, start, step)Các đối số:
rows– Số hàng cần trả về.columns– Số cột cần trả về.start– Mặc định, số tuần tự sẽ bắt đầu từ 1. Để bắt đầu từ một số khác, chỉ định số bắt đầu.step– Mặc định, số sẽ tăng lên 1. Chỉ định số để thay đổi sự tăng/giảm.
Các ví dụ về công thức sử dụng hàm Sequence trong Google Sheets
Dưới đây là một số công thức để giúp bạn hiểu cách sử dụng từng đối số trong hàm này.
Tạo Số Tuần Tự trong Một Cột Bằng Cú pháp Sequence(rows):
=sequence(10)Công thức Sequence này trong Google Sheets sẽ tạo ra một mảng cột đơn gồm các số từ 1 đến 10. Tức là kết quả sẽ xuất hiện theo chiều dọc.
Tạo Số Tuần Tự trong Một Hàng Bằng Cú pháp Sequence(rows, columns):
Để tạo số tuần tự trong một hàng duy nhất, sử dụng công thức như dưới đây.
=sequence(1,10)Như bạn có thể thấy, tôi đã chỉ định số ‘rows’ là 1 và số ‘columns’ là 10.
Để tạo số tuần tự trong nhiều cột và hàng, hãy sử dụng cú pháp tương tự như ví dụ trên.
Công thức =sequence(2,10) sẽ trả về các số từ 1 đến 10 trong hàng đầu tiên và các số từ 11 đến 20 trong hàng thứ hai.
Trong công thức dưới đây, tôi đang sử dụng tất cả các đối số.
Số Tuần Tự Trong Nhiều Cột:
=sequence(5,5,10,10)
Số Tuần Tự Âm:
Hãy thử công thức sau trên bảng tính của bạn và xem kết quả.
=sequence(10,1,-1,-1)Cách Sử Dụng Hàm Sequence trong Google Sheets để Tạo Số Tuần Tự theo Thứ Tự Ngược (Thứ Tự Giảm Dần)?
Để trả về các số theo thứ tự giảm dần, bạn nên sử dụng cùng một giá trị cho đối số ‘rows’ và ‘start’. Ngoài ra, giá trị ‘step’ nên là số âm.
=sequence(10,1,10,-1)Công thức này sẽ trả về các số 10, 9, 8…1.
Số Tuần Tự Động trong Google Sheets
Để tạo số thứ tự trong một cột, từ đầu đến giá trị trong hàng cuối cùng trong cột khác, chúng ta có thể sử dụng kết hợp hàm Sequence và Match.
Đầu tiên, hãy xem công thức thông thường tạo số thứ tự từ 1 đến 13 trong một cột.
=sequence(13)Thay thế công thức này bằng công thức Sequence động dưới đây.
=ArrayFormula(sequence(MATCH(2,1/(B:B<>""),1)-1))
Trong công thức Sequence động này, hàm Match trả về số hàng của ô cuối cùng có giá trị trong cột B.
Tôi đã giải thích công thức Match ở đây – Địa chỉ Ô cuối không trống bỏ qua ô trống trong một cột trong Excel. Nó liên quan đến Excel nhưng cũng hoạt động tốt trong Google Sheets.
Tôi đã trừ đi giá trị 1 từ số tìm được để điều chỉnh hàng tiêu đề được tính vào.
Để có được số thứ tự này theo thứ tự giảm dần, bạn có thể sử dụng công thức này.
=ArrayFormula(sequence(MATCH(2,1/(B:B<>""),1)-1,1,MATCH(2,1/(B:B<>""),1)-1,-1))Nó tương đương với sắp xếp công thức đầu tiên theo thứ tự giảm dần.
=sort(ArrayFormula(sequence(MATCH(2,1/(B:B<>""),1)-1)),1,0)Hàm Sequence để Tạo Mảng Các Ngày
Đây là một mẹo tiên tiến nữa. Bạn có thể tạo một mảng ngày tuần tự bằng hàm Sequence trong Google Sheets.
Để làm điều đó, bạn phải sử dụng tất cả các đối số trong công thức. Dưới đây là công thức chung để tạo một cột ngày tuần tự.
=sequence(row,column,start_date,step)Công thức để tạo các ngày từ 01/01/2019 đến 15/01/2019 trong một cột:
=sequence(15,1,date(2019,1,1),1)Kết quả sẽ ở định dạng số. Hãy thay đổi nó thành ngày từ Format > Number > Date.
Nếu ngày bắt đầu được lưu trong ô C1, hãy tham khảo bằng cách sử dụng Indirect trong Sequence.
=sequence(15,1,indirect("C1"),1)
