Bạn đã bao giờ nghe về công thức “Index and Match” trong Google Sheets chưa? Đây là một ví dụ tuyệt vời về việc kết hợp các công thức trong các ứng dụng bảng tính như Excel và Google Sheets để tìm kiếm dạng dọc. Bạn có thể sử dụng nhiều điều kiện trong “Index Match” trong Google Sheets.
Nhiều người đã “nghiện” “Index Match”, ngay cả khi họ có thể sử dụng công thức “Vlookup”, họ vẫn sử dụng “Index” và “Match”. Vì vậy, trong bài hướng dẫn này, bạn có thể tìm hiểu cách “Index Match” xử lý nhiều tiêu chí.
Nhiều Điều Kiện trong “Index Match” trong Google Sheets
Dưới đây là một ví dụ về việc sử dụng nhiều Điều Kiện trong “Index Match”.
Trong ví dụ này, tôi có hai sản phẩm điện thoại thông minh trong cột A. Mỗi sản phẩm điện thoại có ba biến thể dựa trên màu sắc.
Các điều kiện để sử dụng trong “Index Match” được đánh dấu trong ảnh chụp màn hình bên dưới. Từ đó, bạn có thể hiểu rằng tôi muốn tìm giá của Smartphone 1 có “Màu sắc” là “Vàng” và “Trạng thái” là “Có sẵn”.
Sản phẩm này nằm ở dòng số 2, và giá là 650.00 đô la.
Vậy làm sao để sử dụng công thức để tìm kiếm ba điều kiện này? Hãy điểm qua!
Công thức “Index Match” để Tìm Kiếm Nhiều Điều Kiện
Dưới đây là công thức để tìm kiếm nhiều điều kiện trong “Index Match” trong Google Sheets.
**Công thức "Index Match" chính**=ArrayFormula(index(A2:D,match(concatenate(G1:G3),A2:A&B2:B&C2:C,0),4))
Tôi nghĩ rằng tôi có thể giải thích công thức này một cách dễ hiểu.
Phần Công thức “Match”
Trong phần này, tôi sẽ giải thích cách công thức “Match” trong công thức trên hoạt động.
Chú ý: Đọc thêm về cách sử dụng hàm “Match” trong Google Sheets.
Cú pháp:
MATCH(key_tìm_kiếm, phạm_vi, [kiểu_tìm_kiếm])
Bước 1:
Kết hợp các điều kiện để sử dụng làm key_tìm_kiếm trong công thức “Match”.
=concatenate(G1:G3)
Nó sẽ trả về chuỗi dưới đây, đây là key_tìm_kiếm trong hàm “Match”.
Kết quả: Smartphone 1VàngCó sẵn
Bước 2:
Giờ hãy xem phạm_vi trong hàm “Match” (bạn sẽ không thấy công thức ArrayFormula trong công thức chính vì nó đã được di chuyển vào phía trước).
=ArrayFormula(A2:A7&B2:B7&C2:C7)
Công thức này trả về giá trị trong cột duy nhất dưới đây.
Hàm “Match” trong công thức “Index Match” chính tìm kiếm key_tìm_kiếm “Smartphone 1VàngCó sẵn” (kết quả Bước 1) trong kết quả của Bước 2 và trả về số 1 là vị trí tương đối vì key_tìm_kiếm được tìm thấy ở hàng đầu tiên của kết quả Bước 2.
Hai bước trên là quan trọng để thực hiện nhiều điều kiện trong công thức “Index Match” trong Google Sheets.
Phần Công thức “Index”
Cú pháp:
INDEX(tham_chiếu, [hàng], [cột])
Trong phần này, tham_chiếu là dải dữ liệu gốc có 4 cột là A2:D và hàng là số 1 trả về bởi công thức “Match” ở trên.
Chúng ta muốn công thức “Index” trả về Giá, nằm trong cột 4.
Vậy phiên bản rút gọn của công thức “Index Match” chính của chúng ta như sau:
=ArrayFormula(index(A2:D,1,4))
Trong đó, thay thế số 1 (hàng) bằng công thức “Match”.
Đó là tất cả. Hy vọng bạn đã hiểu cách sử dụng nhiều điều kiện trong “Index Match” trong Google Sheets.
Kết Luận
Bạn cũng có thể sử dụng công thức “Vlookup” trong trường hợp này. Đây là công thức đó!
=ArrayFormula(vlookup(CONCATENATE(G1:G3),{A2:A10&B2:B10&C2:C10,D2:D10},2,false))
Tương tự như nhiều tiêu chí trong “Index Match”, bạn có thể kết hợp các điều kiện ở đây để sử dụng trong “Vlookup”.
Phần phạm_vi ở đây khác một chút. Ở đây, thay vì sử dụng A2:D trong “Index Match”, tôi đã sử dụng một phạm vi ảo với hai cột. Ba cột đầu tiên được kết hợp thành một và sau đó thêm cột Giá. Vì vậy, cột Index của Vlookup là 2 ở đây.
Thật ra, hai công thức trên không phải là giải pháp tốt nhất. Chúng ta có thể giải quyết cùng một vấn đề này với một công thức FILTER dễ đọc. Hãy xem ví dụ dưới đây!
=filter(D2:D7,A2:A7=G1,B2:B7=G2,C2:C7=G3)
Cảm ơn bạn đã đọc đến đây. Chúc bạn vui vẻ!
Sample_Sheet_16421
