Trong Google Sheets, giống như Hàm Logic AND, chúng ta không thể sử dụng Hàm Logic OR để trả kết quả mở rộng theo cách thông thường. Vậy phải làm sao để giải quyết vấn đề này?
Trong bài viết hướng dẫn nhanh về Google Sheets này, tôi sẽ chia sẻ các giải pháp tạm thời.
Thường ta sẽ sử dụng Hàm Logic OR trong Hàm IF để kiểm tra xem các đối số có đúng theo lý thuyết hay không và trả về một giá trị phù hợp. Nhưng bạn có biết cách sử dụng OR Logic trong Mảng trong Google Sheets không?
Tôi đang nói về việc mở rộng các kết quả liên quan đến Hàm Logic OR trong Google Sheets bằng cách sử dụng ArrayFormula, trong đó chúng ta sẽ thay thế tham chiếu ô A1 bằng một mảng như A1: A.
Ví dụ:
=if(or(A1=”Thứ Bảy”, A1=”Chủ Nhật”),”Cuối Tuần”,”Ngày Làm Việc”)
Công thức mảng dưới đây sẽ không trả về kết quả trong nhiều hàng.
=ArrayFormula(if(or(A1:A=”Thứ Bảy”, A1:A=”Chủ Nhật”), “Cuối Tuần”, “Ngày Làm Việc”))
Hãy cùng tìm hiểu cách sử dụng Hàm Logic OR để trả về một kết quả mảng mở rộng trong Google Sheets.
Hàm Logic OR để Trả về Kết quả Mở Rộng trong Google Sheets
Có 2-3 phương pháp mà bạn có thể theo dõi để có được kết quả mở rộng khi sử dụng kiểm tra Hàm Logic OR trong Hàm IF.
Dưới đây là ba phương pháp đó:
- Sử dụng IF Nội tuyến.
- Sử dụng Toán tử +.
- Sử dụng Một hàm trợ giúp Lambda.
Khi tôi nói về việc mở rộng kết quả, tôi có nghĩa là kết quả là một mảng. Vậy làm thế nào để Sử dụng OR Logic trong Mảng trong Google Sheets?
1. Kết quả mở rộng với Hàm OR Logic bằng cách sử dụng IF Nội tuyến
Hãy xem ví dụ sau về việc chuyển đổi một công thức OR không phải là mảng trong Google Sheets.
Tương tự: Sử dụng IFS và IF Nội tuyến trong Google Sheets.
Tôi có một số con số trong các cột A và B. Hãy bắt đầu áp dụng các thử nghiệm OR Logic bằng cách lồng các công thức IF.
Ví dụ, nếu giá trị trong ô A2 hoặc B2 lớn hơn 0, tôi muốn công thức IF lồng nhau trả về TRUE trong ô G2, ngược lại trả về FALSE.
Công thức OR không phải là mảng: =or(A2 > 0, B2 > 0)
Công thức IF lồng nhau này thực hiện công việc đó!
=if(A2 > 0, TRUE, IF(B2 > 0, TRUE))
Tôi muốn thực hiện kiểm tra hàm OR liên quan đến chức năng này trên nhiều hàng. Tất nhiên, tôi có thể sao chép công thức xuống dưới.
Nhưng tôi muốn có một công thức duy nhất thực hiện kiểm tra logic ở mỗi hàng và tạo ra kết quả mở rộng mảng. Đây là công thức cho bạn!
=ArrayFormula(if(A2:A4 > 0, TRUE, IF(B2:B4 > 0, TRUE, FALSE)))
Kết quả trở thành một mảng mở rộng dưới đây. Và về ví dụ được nêu ở đầu, cuối tuần và ngày làm việc, giờ đây có thể thực hiện như sau!
=ArrayFormula(if(A1:A = "", "", if(A1:A = "Thứ Bảy", "Cuối Tuần", if(A1:A = "Chủ Nhật", "Cuối Tuần", "Ngày Làm Việc"))))
Tôi không khuyến nghị cách sử dụng IF lồng nhau này để thực hiện kiểm tra Hàm Logic OR trong Google Sheets.
Điều này bởi vì nếu có nhiều cột hoặc đối số được liên quan, công thức sẽ trở nên rất khó để viết mã.
2. Thay thế IF Nội tuyến bằng phương pháp Sử dụng Toán tử +
Đây là cách khác để sử dụng Hàm Logic OR để trả về kết quả mở rộng mảng trong Google Sheets. Ở đây, chúng ta sẽ thay thế hàm OR bằng toán tử cộng (+).
=ArrayFormula(if((A2:A4 > 0) + (B2:B4 > 0) > 0, TRUE, FALSE))
Tôi chỉ áp dụng công thức trên ô F2 nhưng kết quả mở rộng xuống hàng dưới. Đây là cách sử dụng công thức này.
Phân tích công thức:
Công thức: =A2 > 0
Kết quả: TRUE
Công thức: =B2 > 0
Kết quả: TRUE
Công thức: =(A2 > 0) + (B2 > 0)
Kết quả: 2
Hy vọng điều này có ý nghĩa.
Để kiểm tra xem A1: A chứa các ngày cuối tuần hay ngày làm việc, hãy sử dụng công thức sau.
=ArrayFormula(if(A1:A = "", "", if((A1:A = "Thứ Bảy") + (A1:A = "Chủ Nhật"), "Cuối Tuần", "Ngày Làm Việc")))
3. Phương pháp Sử dụng Hàm MAP Lambda cho Công thức Mảng OR
Từ ví dụ trên, bạn có thể hiểu rằng chúng ta không thể sử dụng Hàm OR cho kết quả mở rộng mảng trong Google Sheets. Nhưng đợi đã!
Bây giờ, có một phương pháp mới sử dụng chức năng MAP.
Chúng ta có thể mở rộng =or(A2 > 0, B2 > 0) bằng cách sử dụng MAP như sau.
=map(A2:A4, B2:B4, lambda(a, b, or(a > 0, b > 0)))
Vì vậy, chúng ta có thể sử dụng công thức ngắn nhất sau để kiểm tra xem A1: A chứa các ngày cuối tuần hay ngày làm việc.
=map(A1:A, lambda(a, if(a = "", "", if(or(a = "Thứ Bảy", a = "Chủ Nhật"), "Cuối Tuần", "Ngày Làm Việc"))))
Đó là tất cả. Cảm ơn bạn đã ở lại. Chúc bạn vui vẻ!
