Bài viết này sẽ phân tích về các câu lệnh ngôn ngữ trong hàm Query trên Google Sheets. Các câu lệnh bao gồm Select, Where, Group By, Pivot, Order By, Limit, Offset, Label và Format. Nhưng nói trước là mình sẽ bỏ qua các câu lệnh “From”, “Skipping” và “Options” vì chúng không được sử dụng thường xuyên.
Hãy nhớ rằng mình không đề cập đến thứ tự thực thi câu lệnh trong hàm Query trên Google Sheets mà chỉ nói về thứ tự (ưu tiên xuất hiện) của các câu lệnh trong công thức.
Câu Lệnh Đúng Trong Hàm Query Trên Google Sheets
Đúng! Thứ tự trên là cách để sử dụng các câu lệnh ngôn ngữ trong hàm Query trên Google Sheets. Nhưng như bạn đã biết, chúng ta không cần sử dụng tất cả các câu lệnh trong một công thức.
Hãy học cách sử dụng đúng câu lệnh trong hàm Query theo thứ tự của chúng trong công thức trên Google Sheets.
1. SELECT: Từ Khóa Chọn Cột
Công thức sau sử dụng câu lệnh SELECT của Query để chọn các cột ‘Customer’ và ‘Balance’ từ dữ liệu trên (SOA).
=query(A1:F,"Select A,F")2. WHERE: Từ Khóa Điều Kiện Lọc
Câu lệnh WHERE đứng thứ hai trong thứ tự. Câu lệnh SELECT là tùy chọn khi sử dụng câu lệnh WHERE.
Ví dụ: Trả về các hàng trong cột A và F mà tên khách hàng trong cột A là “Customer 1”.
=query(A1:F,"Select A,F Where A='Customer 1'")Nếu bạn không muốn chọn bất kỳ cột cụ thể nào trong công thức, bạn có thể bỏ qua câu lệnh SELECT.
Xem ví dụ sau, nó lọc ‘Customer 1’ như trên nhưng trả về tất cả các cột trong phạm vi.
=query(A1:F,"Where A='Customer 1'")3. GROUP BY: Từ Khóa Kết Hợp Nhóm Hàng
GROUP BY là câu lệnh thứ ba cần sử dụng trong công thức hàm Query trên Google Sheets.
Câu lệnh WHERE là tùy chọn với câu lệnh GROUP BY.
Chỉ sử dụng các cột được chỉ định trong câu lệnh SELECT trong câu lệnh GROUP BY.
=query(A1:F,"Select A, Sum(F) Where A='Customer 1' group by A")Công thức trên sẽ trả về kết quả như bên dưới.
| Customer | sum Balance |
|---|---|
| Customer 1 | 1000 |
| Customer 2 | 2000 |
4. Pivot: Từ Khóa Điều Chỉnh Dữ Liệu
PIVOT là câu lệnh thứ tư trong thứ tự câu lệnh đúng để sử dụng trong hàm Query trên Google Sheets.
Ở đây, từ khóa WHERE không bắt buộc với từ khóa PIVOT vì nó thực chất là để lọc dữ liệu nhưng khuyến nghị lọc các ô trống khi dữ liệu của bạn mở rộng (A1:F thay vì A1:F10).
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot C")Xem thêm một ví dụ khác.
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C)")5. ORDER BY: Từ Khóa Sắp Xếp
ORDER BY là từ khóa thứ năm trong thứ tự câu lệnh đúng trong hàm Query trên Google Sheets.
Tất cả các câu lệnh trước đó (từ khóa hoặc tổ hợp từ khóa) đều là tùy chọn với từ khóa ORDER BY.
Dưới đây là một số ví dụ về công thức Query sử dụng câu lệnh ORDER BY mà không có các câu lệnh trước đó.
=query(A1:F,"Order by A")
=query(A1:F,"Order by A,C")
=query(A1:F,"Order by A Asc")
=query(A1:F,"Order by A Desc")6. LIMIT: Từ Khóa Giới Hạn Số Hàng
Dưới đây là các ví dụ về câu lệnh LIMIT trong thứ tự câu lệnh đúng trong hàm Query trên Google Sheets.
Câu lệnh LIMIT là độc lập và không yêu cầu các câu lệnh khác.
Dưới đây là các công thức ví dụ, có hoặc không sử dụng các câu lệnh khác với LIMIT.
=query(A1:F,"Limit 5")
=query(A1:F,"Select A,E Limit 5")
=query(A1:F,"Select A,E Where A<>'' Limit 5")
=query(A1:F,"Select A, Sum(F) Where A<>'' group by A Limit 1")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot C Limit 1")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Limit 1")7. OFFSET: Từ Khóa Dịch Chuyển Hàng
Câu lệnh OFFSET trong Query có yêu cầu các câu lệnh khác để hoạt động không?
Không! Câu lệnh OFFSET sẽ hoạt động độc lập.
=query(A1:F,"Offset 1")Khi chúng ta sử dụng các câu lệnh khác với từ khóa OFFSET, chúng ta phải tuân theo thứ tự câu lệnh đúng.
Nếu chúng ta tuân theo một thứ tự câu lệnh khác, Google Sheets Query sẽ trả về lỗi #VALUE.
Nó áp dụng cho tất cả các câu lệnh!
Thứ tự câu lệnh đúng khi sử dụng câu lệnh OFFSET trong hàm Query trên Google Sheets:
=query(A1:F,"Select A,E Offset 2")
=query(A1:F,"Select A,E Where A<>'' Offset 2")
=query(A1:F,"Select A, Sum(F) Where A<>'' group by A Offset 1")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot C Offset 1")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Offset 1")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Limit 1 Offset 1")8. Label: Từ Khóa Tùy Chỉnh Nhãn Trường
Câu lệnh LABEL trong Query không cần sự hỗ trợ của các câu lệnh khác.
Hi vọng ví dụ công thức Query dưới đây nói lên điều này.
=query(A1:F,"label A 'Name', B 'Inv'")Còn việc sử dụng câu lệnh LABEL với các câu lệnh khác đứng trước thì sao?
=query(A1:F,"Select A,E Label E 'Amt Cr'")
=query(A1:F,"Select A,E Where A<>'' Label E 'Amt Cr'")
=query(A1:F,"Select A, Sum(F) Where A<>'' group by A Label Sum(F) 'Total Balance'")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot C Label A'Name'")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Label A 'Name'")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Limit 1 Label A'Name'")
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Pivot month(C) Order By A Desc Limit 1 Offset 1 Label A 'Name'")9. Format: Từ Khóa Định Dạng
Để tìm hiểu câu lệnh này, vui lòng đọc bài viết của mình – Cách Định Dạng Ngày Tháng, Giờ Và Số Trong Hàm Query Trên Google Sheets.
Chúng ta có thể sử dụng câu lệnh FORMAT trong hàm Query với hoặc không cần các câu lệnh khác.
=query(A1:F,"format C 'dd-mmm'")FORMAT là câu lệnh cuối cùng trong thứ tự câu lệnh của Query. Bạn có thể kết thúc cú pháp ‘query’ với nó, tiếp theo là tiêu đề như sau.
Cú Pháp Hàm Query: QUERY(data, query, [headers])
=query(A1:F,"Select A, Sum(D) Where A<>'' group by A Order By A Desc Limit 1 Offset 1 Label A 'Name' Format Sum(D) '$##.00'",1)Mình đã bỏ qua câu lệnh PIVOT trong công thức Query trên vì định dạng một tiêu đề Pivot cần một cách khác để làm việc.
Bạn có biết cách định dạng các nhãn Pivot trong Google Sheets Query không?
Nếu không, bạn có thể đọc hướng dẫn này – Cách Định Dạng Hàng Tiêu Đề Pivot Trong Query Trên Google Sheets.
Bạn có thể đánh dấu trang web này vào danh sách trang bạn dùng để kiểm tra câu lệnh đúng trong Query trên Google Sheets khi cần thiết.
